Question

I have a class MapHandler.

I created an object myMaphandler = new MapHandler and called initialize method.
But @userLocationMarker.getPosition() is returning null 🙁

If I’ll comment alert and call @userLocationMarker.getPosition() from Chrome JS console I getting necessary coordinates.

class window.MapHandler

  initialize: (centerLocation) ->
    @makeMap(centerLocation)
    @defineUserLocation()
    alert @userLocationMarker.getPosition()


  makeMap: (centerLocation) ->
    myOptions =
      zoom: 14
      center: centerLocation
      mapTypeId: google.maps.MapTypeId.ROADMAP
    @map = new google.maps.Map(document.getElementById("map_canvas"), myOptions)


  placeMarker: (location, icon_path) ->
    if icon_path
      markerImage = new google.maps.MarkerImage(icon_path, null, null, null, new google.maps.Size(25, 25))
    else
      markerImage = null
    marker = new google.maps.Marker(
      position: location
      map: @map
      icon: markerImage)

  defineUserLocation: () ->
    @userLocationMarker = @placeMarker(null, null)

    handleMap = (position) =>
      pos = new google.maps.LatLng(position.coords.latitude, position.coords.longitude)
      infowindow = new google.maps.InfoWindow(
        map: @map
        position: pos
        content: 'Если это не ваше местоположение - передвиньте маркер'
      )
      @map.setCenter(pos)
      @userLocationMarker.setPosition(pos)

    if navigator.geolocation
      @userPosition = navigator.geolocation.getCurrentPositon(
        handleMap
      )

LINK

Why this occurs and what I should do for avoiding this situation?

Answer 1

You initialize @userLocationMarker with a null position:

@userLocationMarker = @placeMarker(null, null)

And then you set the “real” positon in handleMap:

handleMap = (position) =>
  #...
  @userLocationMarker.setPosition(pos)

which is used as a callback for getCurrentPosition:

if navigator.geolocation
  @userPosition = navigator.geolocation.getCurrentPosition(
    handleMap
  )

The problem is that getCurrentPosition is asynchronous so your alert is getting called before handleMap has been called by getCurrentPosition. Anything that depends on what getCurrentPosition does has to be in the handleMap callback or they need to be prepared to deal with data that hasn’t arrived yet.

There’s also a typo in your example code, you spelled getCurrentPosition wrong in your if navigator.geolocation block.

By the time you try checking the position from the JavaScript console, getCurrentPosition has called handleMap and @userLocationMarker will have had its position properly initialized.