Question

I have a class that inherits from NetConnection, with the following function:

override public function connect(command:String, ... arguments):void
{
    addEventListener(NetStatusEvent.NET_STATUS, onNetStatus);
    super.connect(command, arguments);
}

What I want to do is effectively this:

override public function connect(command:String, ... arguments):void
{
    m_iTries = 0;
    m_strCommand = command;
    m_arguments = arguments;
    addEventListener(NetStatusEvent.NET_STATUS, onNetStatus);
    super.connect(command, arguments);
}

private function onNetStatus(pEvent:NetStatusEvent):void
{
    if (/* some logic involving the code and the value of m_iTries */)
    {
        super.connect(m_strCommand, m_arguments);
    }
    else
    {
        // do something different
    }
}

Is this possible in AS3? If so, how? How would I declare the variable, set it, pass it into the function, etc.? Thanks!

Answer 1

Something like this in connect:

 ...
 // Add m_strCommand to the start of the arguments array:
 m_arguments.unshift(m_strCommand); 
 ...

And in onNetStatus:

if (/* some logic... */)
{
    // .apply calls the function with first parameter as the value of "this". 
    // The second parameter is an array that will be "expanded" to be passed as 
    // if it were a normal argument list:
    super.connect.apply(this, m_arguments);
}

This means that calling e.g. (bogus arguments):

myNetConnection.connect("mycommand", 1, true, "hello");

will result in what amounts to this call from onNetStatus:

super.connect("mycommand", 1, true, "hello");

More about .apply(): http://adobe.ly/URss7b