Question

I have a Clojure proxy statement that was getting large and messy, so I decided to try factoring the code of the beginDrag method redefinition out of the proxy statement, like this:

(defn enhanced-start-drag
  ""
  [pie]
  (let [pobj   (. pie getPickedNode)
    pobj-coll (seq (.. pie getInputManager
               getKeyboardFocus getSelection))]
    (println pobj)
    (println pobj-coll)
    (println "----------")
    (proxy-super startDrag pie)))  ; THIS IS LINE 94 (SEE ERROR MSG)



(defn custom-selection-event-handler [marqueeParent selectableParent]
  (proxy [PSelectionEventHandler]  [marqueeParent selectableParent]
    (decorateSelectedNode [node]
              (let [stroke-color (Color/red)]
                (.setStrokePaint node stroke-color)))
    (undecorateSelectedNode [node]
                (let [stroke-color (Color/black)]
                  (.setStrokePaint node stroke-color)))
    (startDrag [pie]    ; pie is a PInputEvent
           (enhanced-start-drag pie))
    (endStandardSelection [pie]     ; pie is a PInputEvent
              (let [pobj   (.getPickedNode pie)
                slip   (. pobj getAttribute "slip")
                ]
                (swap! *last-slip-clicked*
                   (fn [x] slip))))))

I get the following compile error:

cd /Users/gw/tech/clojurestuff/cljprojects/infwb/src/infwb/
1 compiler notes:

Unknown location:
  error: java.lang.Exception: Unable to resolve symbol: this in this context

core.clj:94:5:
  error: java.lang.Exception: Unable to resolve symbol: this in this context 
    (core.clj:94)

Compilation failed.

As soon as I restore the body of enhanced-start-drag into the body of the proxy statement, everything works.

My question: Is there a way to move the messy details out to a separate function to improve the readability of my code?

Thanks for all your ideas and solutions.

---

UPDATE, 10/27/11: See the comments below. Arthur Ulfeldt was sharp in pointing out that the issue is captured references, and Dave Ray is also correct in saying that all you have to do is add this as a parameter to enhanced-start-drag and then proxy-super will work correctly. When I made the following two changes (without any changes to the body of enhanced-start-drag), my code was working again:

  (defn enhanced-start-drag
    ""
    [pie this]

and

  (startDrag [pie]  ; IN THE PROXY STMT IN custom-selection-event-handler
   (enhanced-start-drag pie this))

BTW, my project uses Dave Ray’s seesaw project to get a Java Swing UI. seesaw is awesome, as are its docstrings and sample code (which are much better than most commercial software). I highly recommend it! And thank you, Dave!

Answer 1

You have been bitten by symbol capture. In this case it is intentaional though you need to stay aware of it. From the doc for proxy-super

Use to call a superclass method in the body of a proxy method. 
Note, expansion captures 'this`

proxy is creating a class that calls a function, when the call gets into enhanced-start-drag the value of this is not where proxy-super expects

you may needs to pass this as another argument into enhanced-start-drag and then call (. saved-this ...) instead of using proxy-super.

---