Question

I have a column in my table called Value1. I then have a computed column, Value2, with the formula of;

(CASE WHEN [Value1] > [Value2] THEN [Value1] ELSE [Value2] END)

I can’t save this as SQL Server balks at the self-reference of the Value2 computed column in the formula.

Is there anything else I can do?

Answer 1

It seems like you need to keep track of not only what value1 is now but also what value1 used to be. You won’t be able to do that with a computed column, because it can only react to the current value, not itself or the previous value.

I suggest an INSTEAD OF TRIGGER as opposed to a computed column. Here is a simple example:

USE tempdb;
GO

CREATE TABLE dbo.SparkyMark
(
    [key]    INT IDENTITY(1,1) PRIMARY KEY,
    [string] VARCHAR(32),
    Value1   INT,
    Value2   INT
);
GO

An INSTEAD OF INSERT TRIGGER:

CREATE TRIGGER dbo.SparkyMark_BeforeInsert
ON dbo.SparkyMark
INSTEAD OF INSERT
AS
BEGIN
    SET NOCOUNT ON;

    INSERT dbo.SparkyMark([string], Value1, Value2)
        SELECT [string], Value1, Value1 FROM inserted;
END
GO

An INSTEAD OF UPDATE TRIGGER:

CREATE TRIGGER dbo.SparkyMark_BeforeUpdate
ON dbo.SparkyMark
INSTEAD OF UPDATE
AS
BEGIN
    SET NOCOUNT ON;

    UPDATE sm
        SET [string] = i.[string],
            Value1 = i.Value1, 
            Value2 = CASE WHEN sm.Value2 < i.Value1 THEN i.Value1 ELSE sm.Value2 END
        FROM
            dbo.SparkyMark AS sm
        INNER JOIN
            inserted AS i
            ON sm.[key] = i.[key];
END
GO

Now let’s insert a couple of rows and prove we can maintain Value2 without ever inserting or updating that column directly:

INSERT dbo.SparkyMark([string], Value1) SELECT 'foo', 3;
INSERT dbo.SparkyMark([string], Value1) SELECT 'foo', 5;

-- Value1 and Value2 are the same:
SELECT * FROM dbo.SparkyMark ORDER BY [key];

-- they will still be the same because the new Value1 > old Value2:
UPDATE dbo.SparkyMark SET Value1 = Value1 + 1;
SELECT * FROM dbo.SparkyMark ORDER BY [key];

-- now they will be one less because the new Value1 < old Value2:
UPDATE dbo.SparkyMark SET Value1 = Value1 - 1;
SELECT * FROM dbo.SparkyMark ORDER BY [key];

-- in row 1 Value1 drops by 2 but Value2 stays the same:
UPDATE dbo.SparkyMark SET Value1 = Value1 - 2 WHERE [key] = 1;
SELECT * FROM dbo.SparkyMark ORDER BY [key];

-- and finally we get both values in both rows equal again:
UPDATE dbo.SparkyMark SET Value1 = Value1 + 5;
SELECT * FROM dbo.SparkyMark ORDER BY [key];

Clean-up:

DROP TRIGGER dbo.SparkyMark_BeforeInsert, dbo.SparkyMark_BeforeUpdate;
DROP TABLE dbo.SparkyMark;
GO