Question

I have a csv files with some special characters such as ‘è’ instead of ‘é’ (the csv file is in french).
So basically I referenced all the special characters and I am trying to write a code with VBA to do it. Unfortunatelly it is not working.
My code is :

Sub ReplaceTest()

' I referenced 35 issues

    Dim replaceWhat(35) As Variant
    Dim replaceBy(35)  As Variant
 ' This is where I reference the special caracters and link them to the good ones
    Application.Sheets("SpecialCaracters").Select
    replaceWhat(35) = Application.Range("A1:A35").Value 
    replaceBy(35) = Application.Range("B1:B35").Value

    Dim i As Integer
    For i = 0 To 34
        Application.Sheets("Sheet1").Select
        ActiveSheet.Columns("A:AH").Select

        Selection.Replace What:=remplacerWhat(i), Replacement:=remplacerBy(i),  LookAt:=xlPart, _
        SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=False, _
        ReplaceFormat:=False
    Next i
End Sub

Any idea? Thanks

Answer 1

Assuming you having something like this:

SpecialCharacters Sheet
\ | A | B
1 | à | a
2 | é | e
3 | ó | o

You can use the following method to iterate through all special character rows and replace the occurrences in another sheet or range.

Option Explicit

Sub ReplaceSpecialCharacters(ReplaceRange As Range)
    Dim SpecialCharSheet As Worksheet
    Dim replaceWhat As String
    Dim replaceBy  As String
    Dim RowIndex As Long

    Set SpecialCharSheet = Sheets("SpecialCharacters")
    For RowIndex = 1 To SpecialCharSheet.UsedRange.Rows.Count
        replaceWhat = SpecialCharSheet.Cells(RowIndex, 1).Value
        replaceBy = SpecialCharSheet.Cells(RowIndex, 2).Value

        ReplaceRange.Replace What:=replaceWhat, Replacement:=replaceBy, _
            LookAt:=xlPart, SearchOrder:=xlByRows, MatchCase:=False, _
            SearchFormat:=False, ReplaceFormat:=False
    Next RowIndex
End Sub

Sub ReplaceSheet1()
    ' If using hard coded range
    ReplaceSpecialCharacters Sheet1.Columns("A:AH")

    ' If using Selection
    ReplaceSpecialCharacters Selection
End Sub