Question

I have a custom Component (cut down)

 TMyComponent = class(TComponent)
 public
    procedure ClientConnected;
 published 
    property ClientSocket: TClientSocket Read ...etc

Right now i have in the OnConnect Event of the ClientSocket Call ClientConnected e.g.

 procedure TForm1.ElvinClient1Connect(Sender: TObject; Socket: TCustomWinSocket);
 begin
   MyComponent1.ClientConnected;
 end;

Is there a way to do this with in the TMyComponent Class with out the need of the external event?

Edit:
Forgot to say that the ClientSocket is not create by the component, its assigned at runtime.

i have also tried having a private Proc

 procedure TMyComponent.OnClientConnected(sender: TObject);
 begin
  ClientConnected;
  if Assigned(oldOnClientConnected) then
   oldOnClientConnected(sender);
 end;

and the a setter for the ClientSocket

 procedure TMyComponent.SetClientSocket(const Value: TClientSocket);
 begin
   fClientSocket := Value;
   oldOnClientConnected:= fClientSocket.OnElvinConnected;
   fClientSocket.oldOnClientConnected:= OnClientConnected;
 end;

But i get the feeling that it will come back to haunt me…

Answer 1

What you need to succesfully hook the events for the assigned ClientSocket (let’s call it child component) is:

• Not “disturb” normal design time behavior: Assign your own event handlers only at runtime
• Save the user (developer) assigned event handlers of the child component
• Make sure to call the saved methods safely.
• Allow runtime reassignment of the child component.
• Document what you’re doing behind the scenes, because developer’s ignorance could mess all the things

For example:

TMyComponent = class(TComponent)
private
  FClientSocket: TClientSocket;
  FSavedClientConnected: TClientConnectedEvent;  //Look for the Event type you want to save
  procedure ClientConnected(AValidFirm: TFirm);  //This method shall have a valid TClientConnectedEvent firm
  procedure Hook;                                //Set my own event handlers to the child component
  procedure UnHook;                              //Free the child component of my own event handlers ant let it as it was before
protected
  procedure Loaded; override;                    //Touch the child component after the container streaming load is finished
  procedure Notification(AComponent: TComponent; Operation: TOperation); override;
                                                 //Stay safe if the child component goes away
public
  destructor Destroy; override;                  //Cleanup the child component if I'm going away
published
  property ClientSocket: TClientSocket read FClientSocket write SetClientSocket;  
                                                 //let's play
end;

procedure TMyComponent.SetClientSocket(Value: TClientSocket);
begin
  if FClientSocket <> Value then
  begin
    UnHook;
    FClientSocket := Value;
    Hook;
  end;
end;

procedure TMyComponent.Hook;
begin
  if (csDesigning in ComponentState) or (csLoading in ComponentState) then Exit;
  if Assigned(FClientSocket) then
  begin
    FSavedClientConnected := FClientSocket.SavedClientConnected;
    FClientSocket.ClientConnected := ClientConnected;
  end;
end;

procedure TMyComponent.UnHook;
begin
  if Assigned(FClientSocket) then
  begin
    FClientSocket.ClientConnected := FSavedClientConnected;
    FSavedClientConnected := nil;
  end;
end;

procedure TMyComponent.Loaded;
begin
  Hook;
end;

destructor TMyComponent.Destroy;
begin
  UnHook;
end;

procedure TMyComponent.Notification(AComponent: TComponent; Operation: TOperation);
begin
  if (AComponent = FClientSocket) and (Operation = opRemove) then
    UnHook;
  FClientSocket := nil;
end;

//the important part!
procedure TMyComponent.ClientConnected(AValidFirm: TFirm);
begin
  DoMyOwnStuffWith(FClientSocket);
  if Assigned(FSavedClientConnected) then
    FSavedClientConnected(AValidFirm);
  //as you see, you can call the saved event before, after or in the mid of your own stuff.
end;

Of course, it doesn’t compile (I’m sure, never tried), but it’s only a brief with the idea. Maybe I miss something, let me know if you get errors to make a review.