Question

I have a dataset with labels which I would like to plot with points colored according to their label. Is there a simple way how to get current line numer inside plot, so that I can determine which category does the point belong to?

I understood that x,y,z are the coordinates of plotted data, but it doesn’t help for the external labels.

This is quite ugly and it works just on sorted dataset with regular distribution.

    data = Import["http://ftp.ics.uci.edu/pub/machine-learning-databases/iris/iris.data"];
    data = Drop[data, -1]; (*there one extra line at the end*)
    inData = data[[All, 1 ;; 4]];
    labels = data[[All, 5]];
    ListPlot3D[inData,
      ColorFunction -> 
        Function[{x, y, z}, 
          If[y < 0.33, RGBColor[1, 1, 0.], 
               If[y < 0.66, RGBColor[1, 0, 0.], RGBColor[1, 0, 1]]
          ]
        ]
    ]

Expected result:

Answer 1

Suppose that points is the lists of coordinates and labels a list of the corresponding labels so for example

points = Flatten[Table[{i, j, Sin[i j]}, 
   {i, 0, Pi, Pi/20}, {j, 0, Pi, Pi/10}], 1];
labels = RandomChoice[{"label a", "label b", "label c"}, Length[points]];

Each label corresponds to a colour which I’m writing as a list of rules, e.g.

rules = {"label a" -> RGBColor[1, 1, 0], 
   "label b" -> RGBColor[1, 0, 0], "label c" -> RGBColor[1, 0, 1]};

Then the points can be plotted in the colour corresponding to their label as follows

ListPointPlot3D[Pick[points, labels, #] & /@ Union[labels], 
   PlotStyle -> Union[labels] /. rules]

Edit

To colour individual points in a ListPlot3D you can use VertexColors, for example

ListPlot3D[points, VertexColors -> labels /. rules, Mesh -> False]