Question

I have a file like this: (data.dat)

 1  1            1  1            1  1            1  1            1  1            1  1            1  1            1  1
 2  2            2  2            2  2            2  2            2  2            2  2            2  2            2  2
 3  3            3  3            3  3            3  3            3  3            3  3            3  3            3  3
 4  4            4  4            4  4            4  4            4  4            4  4            4  4            4  7
 5  5            5  5            5  5            5  5            5  5            5  5            5  5            5  9
 6  6            6  6            6  6            6  6            6  6            6  7            6  7           
 7  9            7  7            7  7            7  7            7  7            7  8            7  9         
 8 10            8  9            8  9            8  8            8  8            8  9                       
                 9  11           9  10           9  9            9  9            9  10                      
                10  12          10  11                          10  10          10  11                    

The odd columns are simple line counters (NR), the even columns are simple values. I would like to get those values, in which the second (or even) colum values are the same in all even columns, i.e. I should get this output:

1
2
3
9

I have already tried to make this line, but something is wrong:

awk '{arr1[$1]=$2;arr2[$3]=$4;arr3[$5]=$6;arr4[$7]=$8;arr5[$9]=$10;arr6[$11]=$12;arr7[$13]=$14;arr8[$15]=$16;}END{for(x in arr1) if(x in arr2 && x in arr3 && x in arr4 && x in arr5 && x in arr6 && x in arr7 && x in arr8) print arr1[x];}' data.dat | sort -n

Is there a better way, by the way?

UPDATE: The real problem is that the array indices are different. So, the arr[…] method does not work… 🙁

Answer 1

This would work –

awk '
BEGIN{x=0}
{if (x<NF) x=NF;for (i=2;i<=NF;i+=2) a[$i]++} 
END{x=x/2;for (y in a) if (x==a[y]) print y}' INPUT_FILE

Explanation:

1. We set a variable x=0 in the BEGIN statement.
2. We use this variable to get to find out maximum number of fields (This is useful later).
3. We store value of every second column to an array and get their number of occurrences.
4. We divide the variable x by 2 to verify maximum number a value can occur in every second column.
5. If the occurrences of numbers in an array matches this variable it means they are present in every second column.

Test: with your sample file

[jaypal:~/Temp] awk '
BEGIN{x=0}
{if (x<NF) x=NF;for (i=2;i<=NF;i+=2) a[$i]++} 
END{x=x/2;for (y in a) if (x==a[y]) print y}' file
2
3
9
1

You can either pipe the output to sort -n to get it in order or use this –

awk '
BEGIN{x=0}
{if (x<NF) x=NF;for (i=2;i<=NF;i+=2) a[$i]++} 
END{x=x/2;for (i=1;i<=length(a);i++) if (x==a[i]) print i}' INPUT_FILE