Question

I have a flash game. I want to send my score to the database by .php. How can i do that? I have written some posts but i couldn’t figure it out how. What should i do in actionscript 3 side and php side? my database name is my_db and my variable is _score.

Answer 1

First you need to create an URLLoader and store the variables you want to send into the header of the request.
After loading the URL and sending the variables we listen for the COMPLETE event so we can get variables from PHP back to Flash.

ActionScript 3 Code:

private function SendScore(score:int) {
    //Use URLVariables Class to store our Variables and send them to our URL
    var variables:URLVariables = new URLVariables();
    //you can create as many variables you want (variables.variablename);
    variables.score = score;
    //URLLoader to load the URL
    var urlloader:URLLoader = new URLLoader;
    //Simple URLRequest with our URL
    var urlrequest:URLRequest = new URLRequest('http://www.mysite.com');
    //We set the method to POST. You can also use GET
    urlrequest.method = URLRequestMethod.POST;
    //We declare our set of variables to the data of our urlrequest
    urlrequest.data = variables;

    //We load the URL           
    urlloader.load(urlrequest);
    //We need to listen to an Event.COMLETE when we want to load variables FROM PHP
    urlloader.addEventListener(Event.COMPLETE, CompleteHandler, false, 0, true);
    //With  the listening to IOErrorEvent.IO_ERRORwe can intercept an error and can use it for Debugging
    urlloader.addEventListener(IOErrorEvent.IO_ERROR , ErrorHandler, false, 0, true);
}

//CompleteHandler will be used when the Load of the URL is completed
private function CompleteHandler(e:Event) {
    //Received Variables from PHP script
    var vars:URLVariables = new URLVariables(e.target.data);
    //You can access all variables from PHP with vars.xxxx
    //Example: vars.var1, vars.var2
    if(vars.success) trace('Saving succeeded');
    else ('Saving failed');
}

//ErrorHandler to receive error messages and don't fire exception errors
private function ErrorHandler(e:IOErrorEvent) {
    trace('Error occured');
}

In PHP we receive the variables with the method POST from Flash and can use them with $_POST[‘xxx’]. We insert the score into a database and we check if the INSERT was a success or not and send this variable back to the “browser”/Flash.

PHP Code (I’m using PDO for database operations: http://php.net/manual/de/book.pdo.php):

try {
    //Establishing database connection with PDO
    $DB = new PDO($dsn, $user, $pw, array(PDO::MYSQL_ATTR_USE_BUFFERED_QUERY => true));
} catch (PDOException $e) {
    //Error catching
    print "Connection to Database failed: " . $e->getMessage() . "<br />";
    die();
}

//Create a SQL statement, prepare it and execute it to INSERT the data into database
//the "variables.score" from AS3 can be read with $_POST['score'], cause we used POST as method
$sql = "INSERT INTO my_db (is_score) VALUES ('".$_POST['score']."');";
$stmt = $DB->prepare($sql);
$stmt->execute();

//Here we send back a variable to AS3:
//If you want to send more variables back use the & sign to append more variables
//example: 'succeds=true&var1=this&var2=there'
//Can be read in CompleteHandler with vars.success
if($stmt->rowCount() > 0) echo('success=true');
else echo('success=false');