Question

I have a flex application which connects to a database. There are several servers on which the databases run. Currently, I have a textboxes ‘host’ and ‘port’ where user can specify to which database they want to connect. I would like to change it to a ComboBox with a list of hosts. I know how to hardcode it in the application, but I would prefer the application to read an xml (or other) file on startup and populate the ComboBox with its contents (in case the databases IPs change in the future). The XML would look somewhat like that:

<root>
   <host ip="123.123.123.123" port="1234"/>
   <host ip="255.255.255.123" port="2700"/>
   <host ip="18.12.65.123" port="1270"/>
</root>

How do I do that? I would like to host the file on server together with the application.

Answer 1

You should load the file from the server (using the URLLoader class)
Then you can read the data of the loader.

For example:

private var loader:URLLoader;
private function init():void {
    loader=new URLLoader();
    loader.addEventListener(Event.COMPLETE, dataLoaded);
    loader.dataFormat=URLLoaderDataFormat.TEXT;
    var req:URLRequest=new URLRequest("http://my-server/path/to/file");
    loader.load(req);
}

private function dataLoaded(e:Event):void {
    loader.removeEventListener(Event.COMPLETE, dataLoaded);
    var data:String=loader.data;

    //If the file is a flat text file (with 123.123.123.123:1234 on each line)
    var lines:Array=data.split("\n");
    for each(var line:String in lines) {
        var i:Array=line.split(":");
        trace("ip: " + i[0]);
        trace("\nport: " + i[1]);
    }

    //If the file is an xml, do this
    var x:XML=new XML(data);
    for each(var host:XML in x.host) {
        trace("ip: " + host.@ip);
        trace("\nport: " + host.@port);
    }
}

And yes, you can use relative urls