Question

I have a global DataSet called ds_SortPlan that I am using to map strings that match a certain regex pattern to an integer.

Private Function MatchDestination(ByVal code As String) As Integer
    Dim m As Match
    For Each tempRow As Data.DataRow In ds_SortPlan.Tables("MatchCode_Lookup").Rows
        m = Regex.Match(code, tempRow.Item("Match_String"))
        If m.Success Then
            Return tempRow.Item("ID")
            Exit Function
        End If
    Next tempRow
    Return 0
End Function

This seem like a very slow and clunky way of doing this. 🙁
Is there a better way to set up a regex that will take a String code and try to match it against multiple patterns returning an associated ID number.

I would like to keep the DataSet if at all possible since there are lots of dependencies on it.

Any advice is appreciated!

Answer 1

If you are calling this function often, you could store the patterns and reuse them, instead of reading them from the DB each time

Private Function MatchDestination(ByVal input As String) As Integer
    Static patterns As List(Of KeyValuePair(Of Integer, String))

    If patterns Is Nothing Then
        patterns = New List(Of KeyValuePair(Of Integer, String))
        For Each row As DataRow In ds_SortPlan.Tables("MatchCode_Lookup").Rows
            Dim entry = New KeyValuePair(Of Integer, String)( _
                DirectCast(row.Item("ID"), Integer), _
                DirectCast(row.Item("Match_String"), String) _
            )
            patterns.Add(entry)
        Next
    End If

    For Each pattern As KeyValuePair(Of Integer, String) In patterns
        If Regex.IsMatch(input, pattern.Value) Then
            Return pattern.Key
        End If
    Next
    Return 0
End Function

Note: You don’t need Exit Function after Return. Return replaces the old Exit Function from VB6.