Question

I have a large excel file that is used to aggregate tracking for issues across multiple clients and I need to divide it into smaller files based on the clients.

Here’s what I’ve got so far: I’ve built a python script that divides the file into the appropriate client-specific files and applies the correct header row to all of them, but it produces CSVs which are ugly. My boss wants to apply some formatting, so what I need to do is (for all CSVs in the directory):

1. convert each file from CSV to .xls (or .xlsx) so it will hold the formatting

2. Auto-fit column widths

3. Make the first row bold (and perhaps apply a color to the row)

So far I’m guessing I can probably do this with either pyWin32 or pyExcelerator, but considering how minimal the changes I’m looking to make are it may be easier to do this as a VB script or a macro or something, but I don’t really know those tools.

Answer 1

The simplest way would be to use VBA

Here’s a quick macro to loop thriugh a folder of csv’s open, apply autofit and save as .xlsx

Note:

1. It utilises early binding, therefore requires a reference to the Scripting Runtime. Can easily be altered to late binding if you prefer.
2. For clarity I have ommitted error handling and various speed optimisations. Whether it’s safe enough or fast enough will depend on your intended use and number and size of files.

---

Sub FormatCSVs()
    Dim fso As FileSystemObject
    Dim pth As String
    Dim fl As File
    Dim wb As Workbook
    
    Set fso = New FileSystemObject
    pth = "C:\Test" ' <-- replace with your path, or add a folder selection dialog>
    For Each fl In fso.GetFolder(pth).Files
       If StrComp(fso.GetExtensionName(fl.Path), "csv", vbTextCompare) = 0 Then
            Set wb = Workbooks.Open(fl.Path)
            With wb.Sheets(1)
                .UsedRange.EntireColumn.AutoFit
                .Rows(1).Font.Bold = True
                .Rows(1).Interior.ColorIndex = 3
            End With
            wb.SaveAs pth & "\" & fso.GetBaseName(fl.Path), xlOpenXMLWorkbook
               ' or use xlExcel8 for .xls
            wb.Close
        End If
    Next
    
    Set fl = Nothing
    Set fso = Nothing
End Sub