Question

I have a large table and want to create a smaller table that systematically picks out one of every 5 records from the original. How best to do this?

This means it should have every row with id ending in 0 and 5 for example.

Thanks.

Answer 1

Assuming that your IDs as auto-incremented and continuous (with no deleted records), the simplest way could something like:

SELECT * 
FROM BigTable 
WHERE ID Mod 5 = 0

You would insert that into the small table like this:

INSERT INTO SmallTable
    SELECT * 
    FROM BigTable 
    WHERE ID Mod 5 = 0

If your primary key ID is not sequential you can do this:

SELECT BigTable.*
FROM   (SELECT ID,
               (SELECT COUNT(ID) + 1
                FROM   BigTable AS A
                WHERE  A.ID < B.ID) AS RowNum
        FROM   BigTable AS B) AS C
       INNER JOIN BigTable
         ON C.ID = BigTable.ID
WHERE  RowNum Mod 5 = 0

Note though that this is OK for a one-time thing as it is quite slow if you have a lot of records.

Better do it in code if you have lots of records (or maybe you have no primary key, which is usually bad btw).
The code below is generic code to copy all records from one table into another (existing) table:

Public Sub CreateSmallTable(largeTableName As String, _
                            smallTableName As String, _
                            interval As Integer)
    Dim rsL As DAO.RecordSet
    Dim rsS As DAO.RecordSet
    Dim db As DAO.Database
    Dim rowNum As Integer
    Set db = CurrentDb()
    ' Open the LargeTable in read-only mode '
    Set rsL = db.OpenRecordset(largeTableName, dbOpenSnapshot)
    If Not (rsL Is Nothing) Then
        Set rsS = db.OpenRecordset(smallTableName, dbOpenTable, dbAppendOnly)
        With rsL
            ' We'll use a generic way to copy all fields from the BigTable '
            Dim fd As DAO.field
            Dim flds As DAO.Fields
            Set flds = rsL.Fields
            .MoveFirst
            ' For each record in the BigTable '
            Do While Not .EOF()
                If rowNum Mod interval = 0 Then
                    rsS.AddNew
                    ' Copy all fields from BigTable to SmallTable '
                    For Each fd In flds
                       rsS.Fields(fd.Name) = .Fields(fd.Name)
                    Next fd
                    rsS.Update
                End If
                rowNum = rowNum + 1
                .MoveNext
           Loop
           .Close
        End With
        rsS.Close
        Set rsS = Nothing
        Set rsL = Nothing
    End If
End Sub

And call it like that (assuming that both BigTable and SmallTable have the same structure and that there are no existing records in SmallTable that could create a primary key violation when trying to inster duplicate records):

CreateSmallTable "Bigtable", "Smalltable", 5

Edit: following HansUp response, changed SQL queries to use Mod instead of its functional version: (Round(ID/5) = ID/5). He’s right, no need to make it more complex than it needs to be.