Question

I have a list with a string inside it and I need to have that deconstructed Char by Char and put into a list as Integer instead but I’m stymied by the types

What i have is a txt file that i read into monad:

getTxt = do
  y <- readFile "foo.txt"
  return y

foo only contains this:

"1234567890\n"

then I thought I was close with sequence but that gets me this list:

["1","2","3","4","5","6","7","8","9","0"] :: [[Char]]

but I need [Integer]. ord will take Char -> Int but how do I read that [Char] -> [Int] ? And after all these trial and only error, don’t I need to filter out that last new line in the end?

Any suggestions?

Answer 1

If you use ord, the types match, but it’s not what you want because ord gives you
the ascii value, not the numeric value: ord 5 is 53, not 5. You could subtract
48 to get the digit, then roll the digits up into a single number, but it would be
easier to use a library function. The most straightforward choice is read:

getInt :: IO Integer
getInt = do
    y <- readFile "foo.txt"
    return (read (takeWhile (/='\n') y))

As in the linked answer,
the best solution here is to use reads.

reads finds a list of possible matches,
as pairs of (match,remainingstring),
which works well for you because it will automatically leave the newline in the remaining string,

*Main> reads "31324542\n" :: [(Integer,String)]
[(31324542,"\n")]

Let’s use that:

findInt :: String -> Maybe Integer
findInt xs = case reads xs of              -- have a look at reads xs
    ((anint,rest):anyothers) -> Just anint -- if there's an int at the front of the list, just return it
    _ -> Nothing                           -- otherwise return nothing

Maybe‘s a handy data type that lets you have failure without crashing the program or doing exception handling.
Just 5 means you got output and it’s 5. Nothing means there was a problem, no output.

addTen :: FilePath -> IO ()
addTen filename = do
    y <- readFile filename
    case findInt y of 
       Just i -> putStrLn ("Added 10, got "++show (i+10))
       Nothing -> putStrLn ("Didn't find any integer at the beginning of " ++ filename)

Which gives you:

*Main> addTen "foo.txt"
Added 10, got 1234567890

---

If you just want the integers the characters represent, you can put import Data.Char at the top of your file and do

ordzero = ord '0'   -- handy constant, 48, to unshift the ascii code to a digit.

getInts :: FilePath -> IO [Int]          -- ord gives the smaller Int, not Integer
getInts filename = do
    y <- readFile filename
    return [ord achar - ordzero | achar <- takeWhile isDigit y]

This takes the characters of the string y for as long as they’re digits,
then finds their ord, subtracting ord '0' (which is 48) to turn '4' into 4 etc.