Question

I have a macro below that iterates along bits in an integer. I would like to integrate the collect capability of the loop like this:

 (loop for x in '(a b c d e)
      for y in '(1 2 3 4 5)
      collect (list x y) )

How should I modify the macro below to accomplish the above?

(defmacro do-bits ((var x) &rest body)
  "Evaluates [body] forms after binding [var] to each set bit in [x]"
  (let ((k (gensym)))
    `(do ((,k ,x (logand ,k (1- ,k))))
         ((= ,k 0))
       (let ((,var (logand ,k (- ,k))))
         ,@body))))

Answer 1

here’s a simple macro with-collector that should do the trick:

(defmacro with-collector ((&optional (collector-name 'collect)) &body body)
  (let ((result (gensym)))
    `(let ((,result (list)))
       (flet ((,collector-name (arg) (push arg ,result)))
         (progn ,@body)
         (when ,result
           (nreverse ,result)))))

it uses the name collect by default:

(with-collector ()
  (collect 'a)
  (collect 'b)); => (A B)

but you can use another name if you like (e.g. for nesting or resolving a symbol conflict)

(with-collector (foo)
  (foo 'bar)
  (foo 'baz)); => (BAR BAZ)

to integrate it with your macro, just wrap the do form:

(defmacro do-bits ((var x) &rest body)
  "Evaluates [body] forms after binding [var] to each set bit in [x]"
  (let ((k (gensym)))
    `(with-collector ()
       (do ((,k ,x (logand ,k (1- ,k))))
           ((= ,k 0))
         (let ((,var (logand ,k (- ,k))))
           ,@body)))))

and collect will be available in the body:

(do-bits (x 255) (collect x))
; => (1 2 4 8 16 32 64 128)
(do-bits (x 256) (collect x))
; => (256)