Question

I have a output file which is a two dimensional array (this file was output generated after running script written to produce 2D array) and I have to read information under a particular column, say column 1. In other words, how do I read and print out information listed, corresponding to all the rows, under column 1.

Any suggestions?

__DATA__
   1  2  3  4  5  6  7  8  9
   A  B  C  D  E  F  G  H  I
  93  48 57 66 52 74 33 22 91

From the above data I want to extract information column wise, say if I want information from column 1, I should be able to list only the following output.
want to list Then I want

OUTPUT:

1
A
93

Answer 1

Final version after all corrections:

#!/usr/bin/perl

use strict;
use warnings;

my $column_to_show = 0;

while ( <DATA> ) {
    last unless /\S/;
    print +(split)[$column_to_show], "\n";
}

__DATA__
   1  2  3  4  5  6  7  8  9
   A  B  C  D  E  F  G  H  I
  93  48 57 66 52 74 33 22 91

Output:

C:\Temp> u
1
A
93

Explanation of print +(split)[$column_to_show], "\n";:

perldoc -f split:

Splits the string EXPR into a list of strings and returns that list.
…
If EXPR is omitted, splits the $_ string. If PATTERN is also omitted,
splits on whitespace (after skipping any leading whitespace).

So: (split)[3] selects the fourth element of the list returned by split. The + in front of (split) is necessary to help perl parse the expression correctly. See perldoc -f print:

Also be careful not to follow the
print keyword with a left parenthesis
unless you want the corresponding
right parenthesis to terminate the
arguments to the print — interpose a +
or put parentheses around all the
arguments.

I thoroughly recommend every Perl programmer to occasionally skim through all of the documentation perldoc perltoc. It is on your computer.