Question

I have a perl script that processes millions of lines of performance data, so I need a way to store metric information efficiently. I discovered perl’s vec() function, which allows you to manipulate the bits of a string directly. This can be used to simulate an array, in a memory efficient manner.

And it works great for storing integer values. But for floating point values, it doesn’t work so well.

Here is an example:

#!/usr/bin/perl

my ($s) = '';

vec($s, 0, 32) = 1234;
vec($s, 1, 32) = 12.34;
vec($s, 2, 32) = pack('f', 12.34);

print "1st vec: " . vec($s, 0, 32) . " (should be '1234')\n";
print "2nd vec: " . vec($s, 1, 32) . " (should be '12.34')\n";
print "3rd vec: " . unpack ('f', vec($s, 2, 32)) . " (should be '12.34')\n";

Running this code, on my machine (Mac OS X 10.6.7, perl 5.8.9) returns the following:

1st vec: 1234 (should be '1234')
2nd vec: 12 (should be '12.34')
3rd vec:  (should be '12.34')

As you can see, in the simple case, perl just rounds the floating point number down to the nearest whole integer. I have even tried to get fancy by using pack()/unpack(), but that just zeros out all of the bits.

I’ve tried several more variations, increasing the # of bits, Googling around, etc. to no avail. This really seems like it should work, since at the end of the day, it’s all just bits.

Thanks.

Answer 1

vec only writes integer, which is why 12.34 in the second example is converted to 12. The packed string in the third example is converted to a 0, and unpack(‘f’, 0) fails.

One solution is to write the packed value as integer,

  vec($s, 2, 32) = unpack('L', pack('f', 12.34));
  print unpack('f', pack('L', vec($s, 2, 32))), "\n";

However, it is better / fastest to not use the detour via vec at all, and instead use the 4 argument version of substr, i.e., specifying (expr, offset, length, replacement):

 substr($s, 2*4, 4, pack("f", 12.34));
 print unpack("f", substr($s, 2*4)), "\n";