Question

I have a perl script using CGI.

The browser calls it with some parameters.

I want to take those parameters, modify some of them and then send back a redirect with a new querystring representing the modified parameters.

I know that I could do this, like this:

my $cgi = CGI->new()
my %vars = $cgi->Vars
$vars{'modify_me'} .=' more stuff';

my $serialized = join '&', map {$_.'='.$cgi->escapeHTML($vars{$_})} keys %vars;

However, this just feels like it might be missing something. In addition, it doesn’t do anything to handle multivalued parameters. Who knows what else it fails to do.

So, is there a module out there that just deals with this problem? I’m not interested in reinventing a wheel that a more talented wright wrought. Right?

Answer 1

The URI module is your friend. It has a query_form method that takes a hash, hashref or arrayref of parameters and generates a query string from it.

It will URL Encode your data for you (and note that you do want it URL Encoded and not HTML Encoded).

So you might have something like:

#!/usr/bin/perl

use strict;
use warnings;
use CGI;
use URI;

my $q = CGI->new;

my @data = map {
        my $name = $_;
        my @values = $q->param($name);
        my $value;
        if (scalar @values == 1) {
            ($value) = @values;
        } else {
            $value = \@values;
        }

        if ($name eq "foo") {
            $value = "replaced";
        }
        ($name, $value);
    } $q->param;

my $uri = URI->new('http://example.com/myAlternative.cgi');
$uri->query_form(\@data);

print $q->redirect(
    -uri=> $uri,
    -status => 301
     );