Question

I have a pl/java class in a running Oracle database that I have misplaced the source code to.

Is there anyway to get the java bytecode back out the database so I could run it against a decompiler?

I’ve already checked ALL_SOURCE and Oracle claims it doesn’t have the source code.

Answer 1

I had to do this myself recently, and put together a Groovy script to do it. You need to modify the connection details and make sure you’ve got Oracle database drivers on your classpath

import groovy.sql.Sql

// Change the following to your requirements ...
def extractRoot = "extracted-classes/"    // Directory to extract classes into
def user = 'SCOTT'                        // Schema user
def password = 'tiger'                    // Yes, it's the password
def host = 'localhost'                    // Database host
def sid = 'orcl'                          // Database SID
def port = 1521                           // Database listener port

def saveBlob(blob, root, name, extension) {
    def byteStream = blob.getBinaryStream()
    def bytes = new byte[blob.length()]
    byteStream.read(bytes)
    def dir = root + name.replaceAll(/\/[^\/]+$/, '')
    if (dir != name) {
        new File(dir).mkdirs()
    }
    def f = new File(root + name + extension)
    println "Writing ${f.getCanonicalPath()}"
    f.delete()
    f.withOutputStream { s ->
        s.write(bytes)
    }
}

sql = Sql.newInstance("jdbc:oracle:thin:@${host}:${port}:${sid}", user,
                      password, 'oracle.jdbc.driver.OracleDriver')

sql.eachRow("select name from all_java_classes where owner = ${user}") {
    sql.call('''
        declare
            b blob;
        begin
            dbms_lob.createtemporary(b, FALSE);
            dbms_java.export_class(?, ?, b);
            ? := b;
        end;''', [it.name, user, Sql.BLOB]) { blob ->
            saveBlob(blob, extractRoot, it.name, '.class')
    }
}

sql.eachRow("select dbms_java.longname(object_name) \"name\" from all_objects where object_type = \'JAVA RESOURCE\' and owner = ${user}") {
    sql.call('''
        declare
            b blob;
        begin
            dbms_lob.createtemporary(b, FALSE);
            dbms_java.export_resource(?, ?, b);
            ? := b;
        end;''', [it.name, user, Sql.BLOB]) { blob ->
            saveBlob(blob, extractRoot, it.name, '')
    }
}