Question

I have a plsql procedure to delete records from child and parent tables.

I would like to raise exception when child record found.

How can I do this?

CREATE OR REPLACE PROCEDURE myproc(
    p_id       number,
    p_id2      number,
    p_par3      number)
AS
BEGIN
 DELETE FROM   child_table
            WHERE   id1 = p_id and par=p_par3;

    DELETE FROM   parent_table
            WHERE   no = p_id2;
COMMIT;

EXCEPTION   
    WHEN OTHERS
    THEN
        --raise
END myproc;
/

Answer 1

Remove the exception block if you don’t want to catch the exception !

CREATE OR REPLACE PROCEDURE myproc(p_id NUMBER, p_id2 NUMBER, p_par3 NUMBER) AS
BEGIN
   DELETE FROM child_table
    WHERE id1 = p_id
      AND par = p_par3;

   DELETE FROM parent_table WHERE no = p_id2;
   COMMIT; /* do you really want to commit in a procedure? */
END myproc;

You don’t have to catch them all (exceptions are not pokemon). If you really insist on catching and re-raising you can use RAISE or RAISE_APPLICATION_ERROR:

EXCEPTION
   WHEN OTHERS THEN
      raise_application_error(-20001 /* user-defined exception number 
                                        between -20999 and -20000 */,
                              'your user-defined exception message',
                              TRUE /* this will preserve the error stack */
                              );
END;

If you want to be more specific and trap only the child exception, you will have to define the exception number because there is no predefined exception in PL/SQL for this error:

CREATE OR REPLACE PROCEDURE myproc(p_id NUMBER, p_id2 NUMBER, p_par3 NUMBER) AS
   child_exists EXCEPTION;
   PRAGMA EXCEPTION_INIT(child_exists, -2292); /* raises ORA-02292 */
BEGIN
   DELETE FROM child_table
    WHERE id1 = p_id
      AND par = p_par3;

   DELETE FROM parent_table WHERE no = p_id2;
   COMMIT; /* do you really want to commit in a procedure? */

EXCEPTION
   WHEN child_exists THEN
      -- do something
      RAISE;
END myproc;