Question

I have a problem getting file modified time as julian date. My Delphi 2010 looks like this:

AHandle := FindFirstFile(PChar('C:\*'), FindData);
if (AHandle <> INVALID_HANDLE_VALUE) then
begin
     repeat
           if (FindData.dwFileAttributes And FILE_ATTRIBUTE_DIRECTORY = 0) then
                ModifJulianDate := FileTimeToJulianDate(FindData.ftLastWriteTime);

     until Not FindNextFile(AHandle, FindData);
end;

The problem is: FileTimeToJulianDate() returned result has one hour offset, ie. if the file’s modified time is 10:01, this code returns 9:01!!

How can I fix this?

Answer 1

The functionality that you are looking for, assuming your answer is accurate, is most easily implemented using FileTimeToLocalFileTime.

function UTCFileTimeToLocalDateTime(const UTCFileTime: TFileTime): TDateTime;
var
  LocalFileTime: TFileTime;
  LocalSystemTime: TSystemTime;
begin
  if not FileTimeToLocalFileTime(UTCFileTime, LocalFileTime) then
    RaiseLastOSError;
  if not FileTimeToSystemTime(LocalFileTime, LocalSystemTime) then
    RaiseLastOSError;
  Result := SystemTimeToDateTime(LocalSystemTime);
end;

Or if you prefer to use SystemTimeToTzSpecificLocalTime then do so like this:

function UTCFileTimeToLocalDateTime(const UTCFileTime: TFileTime): TDateTime;
var
  UTCSystemTime, LocalSystemTime: TSystemTime;
begin
  if not FileTimeToSystemTime(UTCFileTime, UTCSystemTime) then
    RaiseLastOSError;
  if not SystemTimeToTzSpecificLocalTime(nil, UTCSystemTime, LocalSystemTime) then
    RaiseLastOSError;
  Result := SystemTimeToDateTime(LocalSystemTime);
end;