Question

I have a program that is encrypted with Blowfish in a file and a second perl program that prompts for a passphrase that is used to decrypt it into a string, I would like to not have to write the decrypted source to the hard drive ever, although having it in memory isn’t really a problem as those running the program already know the source. I thought I might use eval but the program I need to run has a lot of input/output using Curses and stuff so eval wont work as it only returns the last value… Does anyone have any idea how this could be accomplished?

Answer 1

You can use an @INC hook to perform the decryption. Then you can simply require or use the encrypted program. For example,

# loader.pl
use Crypt::Rot13;
use File::Spec;
sub decrypt_line {
    if ($_ ne '') {
        my ($self, $state) = @_;
        my ($crypt, $key) = @$state;
        $crypt->charge($_);
        ($_) = $crypt->rot13($key);
        return 1;
    }
}
sub load_crypt {
    my ($self, $filename) = @_;
    print "Key?\n";
    chomp(my $key = <STDIN>);
    for my $prefix (@INC) {
        open my $fh, '<', File::Spec->catfile($prefix, "$filename.r13") or next;
        return ($fh, \&decrypt_line, [Crypt::Rot13->new(), $key]);
    }
}
BEGIN {
    unshift @INC, \&load_crypt;
}
require 'hello.pl';

# hello.pl.r13
cevag "Uryyb, jbeyq!\a";

$ perl loader.pl
Key?
13
Hello, world!