Question

I have a program the launches a cmd console with a certain environment. The problem the console is launched by clicking a button, so I can’t create a custom launcher on my own with that environment.

What I want:
Given a file with a set variables (generated by running set command in the custom launched cmd), I want to set up the environment in the current cmd console by reading that file.

Example:

in.txt (note the spaces in same vars on the right side):

var1=c:\program files
path=c:\;c:\bin
var2=d:\folder with libs  

After running the script like: ./script.sh in.txt the environment in the current cmd console should be (output after running set command):

var1=c:\program files
path=c:\;c:\bin
var2=d:\folder with libs

Note: bash scripting can be used inside the script as long as the environment is set right.

Answer 1

I have manged to write the following working script:

• Usage: script.bat file_name
• If file_name not provided prints usage

• Creates a backup file envbkp.bat with environment variables before deleting them for possible restore

  @echo off
  
  set _exitStatus=0
  set _argcActual=0
  set _argcExpected=1
  
  echo.
  
  for %%i in (%*) do set /A _argcActual+=1
  
  if %_argcActual% NEQ %_argcExpected% (
      call :_ShowUsage %0%
      set _exitStatus=1
      goto:_EOF
  )
  
  set _exitStatus=
  set _argcActual=
  set _argcExpected=
  
  if exist ".\envbkp.bat" del ".\envbkp.bat"
  echo @echo off > envbkp.bat
  for /f "tokens=1* delims==" %%a in ('set') do (
      echo set %%a=%%b>> .\envbkp.bat
      set %%a=
  )
  
  for /f "tokens=1* delims==" %%a in ('type %~1') do (
      set %%a=%%b
  )
  goto:_EOF
  
  :_ShowUsage
      echo [USAGE]: %~1 env_file
      echo.
  if NOT "%~2" == "" (
      echo %~2
      echo.
  )
  goto:eof
  
  :_EOF