Question

I have a question regarding copying cells from one sheet to another using VBA.

Question Background:

Sheet1 of an excel spreadsheet contains headers and a number of test observations from multiple test subjects. Each row is an observation of one trial per subject. Each test subject has a static number of observations, i.e. 15 rows. I need to select an individual cell(s) from a specified row(s) and copy them to sheet2 of the same workbook into 1 row per subject. Sheet 2 will contain headers as well. Being new to VBA, and to programming/scripting in general, I’m having some issues wrapping my head around on how to do this. Below is a similar example of the data that I am trying to manipulate. The data set below contains 5 columns. The subject numbers are 1111 and 2222. Each heading of Variable() contains 1 letter, e.g. VariableOne = “a”, VariableTwo = “b”, etc.

Subject – VariableOne – VariableTwo – VariableThree – VariableFour

1111 – a b c d

1111 – e f g h

1111 – i j k l

1111 – m n o p

2222 – a b c d

2222 – e f g h

2222 – i j k l

2222 – m n o p

For example, row 2 (due to headers) of sheet 2 will include the subject number 1111 and values “m” from VariableOne, “f” from VariableTwo, “c” from VariableThree, and “l” from VariableFour. Row 3 of sheet 2 will contain subject #2222 and the values listed in the same position as subject 1111 (the values will be different but their position within the data set will be the same).

I think the code should include 2 loops; one to iterate through subjects and the other to iterate through the actual data. I’m not really sure as to how to go about doing this so if anybody has done this before, I would appreciate the help.

Additionally, I’ve just gone through the book “Microsoft Excel VBA programming for the absolute beginner”, which was a nice introduction to VBA for excel but it didn’t help me with formulating any solutions for my personal VBA/excel needs. Does anyone know of a better source, such as a book, to become more acquainted with the VBA scripting language for excel?

Answer 1

Your question suggests to me that you are looking to copy the values on sheet one in positions m, f, c, and l into a single row on sheet two for each subject. The following does just that (and assumes that you have already manually copied over the headers into the same columns as sheet one). Let me know if my understanding of your question is mistaken and I will attempt to adjust the code sample accordingly.

Sub CopyMySubjectsVariables()

    'I find making worksheet variables helps make code easier to understand
    Dim sheetOne, sheetTwo As Worksheet
    Set sheetOne = Worksheets("Sheet1")
    Set sheetTwo = Worksheets("Sheet2")

    'For the same reason, I set the column numbers to variables when possible
    Dim subjectCol, variableOneCol, variableTwoCol, variableThreeCol, variableFourCol As Integer
    subjectCol = 1
    variableOneCol = 2
    variableTwoCol = 3
    variableThreeCol = 4
    variableFourCol = 5

    'In your example table there are only four observations per subject 
    Dim numObservationsPerSubject As Integer
    numObservationsPerSubject = 4

    'Since Sheet Two also contains headers, the first subject will start on Row 2
    Dim subjectRowOnSheetTwo As Integer
    subjectRowOnSheetTwo = 2

    'Loop through all used rows of sheet one "stepping" from one subject to the next
    Dim subjectStartingRowOnSheetOne As Integer 'This variable is usually called "i" but I wanted to clarify it a bit
    For subjectStartingRowOnSheetOne = 2 To sheetOne.UsedRange.Rows.Count Step numObservationsPerSubject

        'Copy Subject Number/Name/Whatever From Sheet One to Sheet Two
        sheetTwo.Cells(subjectRowOnSheetTwo, subjectCol).Value = sheetOne.Cells(subjectStartingRowOnSheetOne, subjectCol).Value

        'Copy Variable One From the Fourth Row (startingRow+3) of the Subjects Observations ("m"'s position in your example)
        sheetTwo.Cells(subjectRowOnSheetTwo, variableOneCol).Value = sheetOne.Cells(subjectStartingRowOnSheetOne + 3, variableOneCol).Value

        'Copy Variable Two From Second Row (startingRow+1) of Subjects Observations ("f"'s position in your example)
        sheetTwo.Cells(subjectRowOnSheetTwo, variableTwoCol).Value = sheetOne.Cells(subjectStartingRowOnSheetOne + 1, variableTwoCol).Value

        'Copy Variable Three From First Row (startingRow) of Subjects Observations ("c"'s position in your example)
        sheetTwo.Cells(subjectRowOnSheetTwo, variableThreeCol).Value = sheetOne.Cells(subjectStartingRowOnSheetOne, variableThreeCol).Value

        'Copy Variable Three From Third Row (startingRow+2) of Subjects Observations ("l"'s position in your example)
        sheetTwo.Cells(subjectRowOnSheetTwo, variableFourCol).Value = sheetOne.Cells(subjectStartingRowOnSheetOne + 2, variableFourCol).Value

        'Increment the Starting Row on Sheet Two so the next subject starts on a new Row
        subjectRowOnSheetTwo = subjectRowOnSheetTwo + 1

    Next subjectStartingRowOnSheetOne

End Sub

After running this code on your example table, Sheet Two has the following:

1111 m f c l

2222 m f c l