Question

I have a question that I hope someone could help me with. My question involves winforms and the datagridview in Visual Studio 2008. I want to bind my datagridview to a collection of business objects instead of a dataset. I would like to have comboboxes in the datagridview which get its value from one of the properties in the business object. Is this possible? Can someone please provide example code or provide a web page which describes how to do this. Any help would be appreciated.

Thanks,
Greg

Answer 1

Here is a simple data class:

Public Class MyData

  Private _ID As Integer
  Private _ItemValue As String

  Public Sub New(ByVal id As Integer, ByVal itemValue As String)
    _ID = id
    _ItemValue = itemValue
  End Sub

  ReadOnly Property ID() As Integer
    Get
      Return _ID
    End Get
  End Property

  Public Property ItemValue() As String
    Get
      Return _ItemValue
    End Get
    Set(ByVal value As String)
      _ItemValue = value
    End Set
  End Property

End Class

Create a form and place a DataGridView control on it, add this code:

Private myList As New List(Of String)
Private myItems As New List(Of MyData)

Protected Overrides Sub OnLoad(ByVal e As EventArgs)
  MyBase.OnLoad(e)

  myList.Add("First Item")
  myList.Add("Last Item")

  myItems.Add(New MyData(1, "Last Item"))
  myItems.Add(New MyData(2, "First Item"))

  DataGridView1.AutoGenerateColumns = False
  DataGridView1.Columns.Add(New DataGridViewTextBoxColumn() With _
                           {.HeaderText = "ID", _
                            .DataPropertyName = "ID"})
  DataGridView1.Columns.Add(New DataGridViewComboBoxColumn() With _
                           {.HeaderText = "ItemValue", _
                            .DataSource = myList, _
                            .DataPropertyName = "ItemValue"})

  DataGridView1.DataSource = myItems
End Sub

Since you want comboboxes in your grid, you have to set AutoGenerateColumns to false and create them yourself, mapping each column to the property in your class through the DataPropertyName property. For the combobox, you can set its own DataSource for the list of drop down items.