Question

I have a really simple code piece like that;

loadingMc.visible = true;
trace("ok");
// send photo to server
loadingMc.visible = false;

Sending photo takes 3-5 seconds but movie clip becomes visible only for last second of process. I can see “ok” message in output at start of the process. So i assume problem is not redrawing movie clip. Is there any option to force redraw before process starts?

UPDATE:
Sending to server part;

upload.addEventListener(MouseEvent.CLICK, function(evt:MouseEvent):void{
    loadingText.visible = true;
    trace("ok");
    var bmd:BitmapData = new BitmapData(1024,768,true,0);
    bmd.draw(imageArea);
    savePicToServer(bmd);
});

function savePicToServer(bmd:BitmapData):void
{   
    var jpgEncoder:JPGEncoder = new JPGEncoder(85);
    var jpgStream:ByteArray = jpgEncoder.encode(bmd);

    var loader:URLLoader = new URLLoader();
    configureListeners(loader);
    var header:URLRequestHeader = new URLRequestHeader("Content-type", "application/octet-stream");
    var request:URLRequest = new URLRequest("http://localhost/test/upload.php?key=prvkey");
    request.requestHeaders.push(header);
    request.method = URLRequestMethod.POST;
    request.data = jpgStream;
    loader.load(request);
}

In the COMPLETE event;

loadingText.visible = false;

Answer 1

EDIT

Just from reading your code, I don’t see why this should not be working – but FP does strange things sometimes.

In similar cases, I used setTimeout() to force the player to delay the subsequent actions and allow the screen to refresh:

upload.addEventListener(MouseEvent.CLICK, function(evt:MouseEvent):void{
    loadingText.visible = true;
    trace("ok");
    setTimeout( doSave, 10 );
});

private function doSave() : void {
    var bmd:BitmapData = new BitmapData(1024,768,true,0);
    bmd.draw(imageArea);
    savePicToServer(bmd);
}

If this still doesn’t work, perhaps a longer timeout will do the trick – but 10ms usually should be enough to refresh the screen.

EDIT

Another way would be to add and remove an ENTER_FRAME listener to make sure the frame really was refreshed:

upload.addEventListener(MouseEvent.CLICK, function(evt:MouseEvent):void{
    loadingText.visible = true;
    trace("ok");
    addEventListener( Event.ENTER_FRAME, onNextFrame );
});

private function onNextFrame( ev:Event ) : void {
    removeEventListener( Event.ENTER_FRAME, onNextFrame );
    doSave();
}

private function doSave() : void {
    var bmd:BitmapData = new BitmapData(1024,768,true,0);
    bmd.draw(imageArea);
    savePicToServer(bmd);
}