Question

I have a requirement to, within a windows batch file, read the first available line from a text file, pass it to a variable and mark the name\line as used

An example of the file is below.

apple
pear
orange

The script would start with ‘apple’, pass ‘apple’ to a variable to be used later in the script (I know how to do that bit), and then write back that line to read &apple, the ‘&’ works as a marker to say it’s been used.

The file would then look like:

&apple
pear
orange

the next time the batch file is run it would take ‘pear’, pass it to a variable and mark it with a & making it look like:

&apple
&pear
orange

I started by trying to find ‘&’ and then trying to move to the next line, but I’m failing after about 12 hours of trying. This is what I got so far .. not much:

for /f “tokens=1” %l in (‘name.txt’) do (Find /v “&” /v “^—- ^$”) (For /F %n in (%l) do (set NewName=%n))

Thanks

Answer 1

Running this on the.file would modify each line in turn;

@echo off
setlocal enabledelayedexpansion
type nul > the.file.temp
set last=
for /F "tokens=*" %%A in (the.file) do (
    set line=%%A
    if "!line:~0,1!" neq "&" if "!last!" equ "" (
        set last=!line!
        set line=^&!line!
    )
    echo !line! >> the.file.temp
)

echo last value is !last!
type the.file.temp > the.file

(If the line does not begin with & and the variable last is empty, put the line in last & modify line with a leading &. Always append line to a temp file, renaming when done)