Question

I have a result-set below

Rank    cardID      DespatchValue   Spend   SumSpend    Spendtype
0       468612      500                0          0         Despatch
1       468612      500             -8500       -8500       Topup
2       468612      500            -11500       -20000      Topup
3       468612      500             -3500       -23500      Topup

As you can see each spend is added to the Sum spend (via a recursive CTE) which i am happy with.

However the logic needs to work thus

• Despatch value up to initial spend = Spend type Balance
• Anything after that = Top up

So,

I would like to see :

Rank    cardID  DespatchValue   Spend   SumSpend    Spendtype
0       468612  500               0        0        Despatch
?       468612  500             -500    -500        Balance
1       468612  500             -8000   -8500       Topup
2       468612  500             -11500  -20000      Topup
3       468612  500             -3500   -23500      Topup

Any ideas on how to achieve this?

Answer 1

To do a split row, you’ll need to add two more UNION clauses to your CTE. Most recursive CTE’s have an “anchor” and a recursive bit. You’ll need to expand how that recursive bit works. First, you identify when to surpress the “nominal” case, which for you is when the balance transitions from a positive total to negative. In your case that’s “DespatchValue + SumSpend”.

The next two terms will be your “split” rows. Using the inverse of whatever condition is above (ie, only bring back the rows over this “special” condition). The first UNION will be be the “BALANCE” record, taking it down to 0. The second is the remainder of what’s left over.

Here’s what I came up with – note that I added a “subid” column to indicate the “balance” (and to prevent duplicates in the later-on recursion). I also added a “DespatchBalance”, assuming that’s really what you’re checking against. Specifics aside, the general format should be good:

declare @txn as table (
    id int, 
    cardID int, 
    DespatchValue int, 
    Spend int
    --SumSpend int, 
    --Spendtype varchar(50)
)

insert into @txn
                    select 0, 468612, 500, 0--, 0, 'Despatch'
union all select 1, 468612, 500, -8500--, -8500, 'Despatch'
union all select 2, 468612, 500, -11500--, -20000, 'Despatch'
union all select 3, 468612, 500, -3500--, -23500, 'Despatch'


;with x (id, subid, cardID, DespatchValue, Spend, SumSpend, DespatchBalance, Despatch) as 
(
    --Anchor - beginning record
    select id, 0, cardID, DespatchValue, Spend
    , Spend as SumSpend
    , DespatchValue as DespatchBalance
    , 'Despatch' as Despatch
    from @txn
    where id = 0

    UNION ALL       
    -- primary CTE - identify all nominal 'Topup' records
    select t.id, 0, t.cardID, t.DespatchValue, t.Spend
    , x.SumSpend + t.Spend
    , x.DespatchBalance + t.Spend
    , 'Topup' 
    from @txn t
    join x
        on x.id + 1 = t.id
        and x.subid = 0
    where x.DespatchBalance <= 0

    UNION ALL 

    -- These two UNIONs do a split record:

    -- First half of split - the remaining amount to a balance of 0
    select t.id, 1 -- special "subid" to indicate it's a split record
    , t.cardID, t.DespatchValue
    , - x.DespatchBalance
    , x.SumSpend - x.DespatchValue -- only capture the remaing bit above balance
    , 0 -- DespatchBalance should be 0
    , 'Balanace' 
    from @txn t
    join x
        on x.id + 1 = t.id
        and x.subid = 0
    where x.DespatchBalance > 0
        and x.DespatchBalance + t.Spend < 0

    UNION ALL 
    -- Second half of split - record that this is an overflow after "Balance" reached
    select t.id, 0
    , t.cardID, t.DespatchValue
    , t.Spend + x.DespatchBalance
    , x.SumSpend + t.Spend 
    , x.DespatchBalance + t.Spend
    , 'Topup' 
    from @txn t
    join x
        on x.id + 1 = t.id
        and x.subid = 0
    where x.DespatchBalance > 0
        and x.DespatchBalance + t.Spend < 0
)

select *
from x
option (MAXRECURSION 100)