Question

I have a source list of xml in this format:

<metadata>
  <metadatum>
    <description>OnEnter</description>
    <value>Hello World</id>
  </metadatum>
  <metadatum>
    <description>OnLeave</description>
    <value>Goodbye World</id>
  </metadatum>
</metadata>

and a target structure like this:

<friendlyText>
  <onEnter>[Content Here]</onEnter>
  <onLeave>[Content Here]</onLeave>
</friendlyText>

Is it possible to create an XSLT that will map the ‘value’ field in the metadata hierarchy to the proper target node depending on the source ‘description’?

I’m trying to get this done with Altova MapForce; it feels like there should be an interface to allow this, I’m just not finding it.

Answer 1

This transformation is a general solution that can work with any “target structure” that is in a separate XML document:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:my="my:my" exclude-result-prefixes="my">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:variable name="vUpper" select=
  "'ABCDEFGHIJKLMNOPQRSTUVWXYZ'"/>
 <xsl:variable name="vLower" select=
  "'abcdefghijklmnopqrstuvwxyz'"/>

 <my:target>
  <friendlyText>
    <onEnter>[Content Here]</onEnter>
    <onLeave>[Content Here]</onLeave>
  </friendlyText>
 </my:target>

 <xsl:variable name="vTarget" select="document('')/*/my:target/*"/>

 <xsl:variable name="vMeta" select="/*/metadatum"/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="/">
     <xsl:apply-templates select="$vTarget"/>
 </xsl:template>

 <xsl:template match="friendlyText/*/text()">
  <xsl:value-of select=
  "$vMeta[translate(description, $vLower, $vUpper)
        =
          translate(name(current()/..), $vLower, $vUpper)
          ]/value"/>
 </xsl:template>
</xsl:stylesheet>

when applied on the provided XML document (corrected to be made well-formed):

<metadata>
    <metadatum>
        <description>OnEnter</description>
        <value>Hello World</value>
    </metadatum>
    <metadatum>
        <description>OnLeave</description>
        <value>Goodbye World</value>
    </metadatum>
</metadata>

produces the wanted, correct result:

<friendlyText xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:my="my:my">
   <onEnter>Hello World</onEnter>
   <onLeave>Goodbye World</onLeave>
</friendlyText>

Do note: Only for convenience, the “target structure” is inline here. In a real world case it would be better to keep the “target structure” in a separate file and to load it using the document() function. Only the line:

 <xsl:variable name="vTarget" select="document('')/*/my:target/*"/>

will need to be changed to:

 <xsl:variable name="vTarget" select="document('someFileUrl')/*"/>