Question

I have a SP that updates some rows and I want to update the SortOrder column I have with it’s position in the select – here is part of my code:

UPDATE StagingCategoryItems 
    SET IsDeleted = 0,
    ModifiedOn = GETDATE(),
    ModifiedBy = 'DragDropSP' 
    WHERE ItemID IN (
    SELECT ItemID
     FROM StagingCategoryItems 
       WHERE ManufacturerID=@ManufacturerID 
       AND CategoryID=@CategoryID
     AND ItemID IN 
     (
    SELECT items
              FROM dbo.Split(@InIds,',')  
        ) 
    AND IsDeleted=1
    )
    AND ManufacturerID=@ManufacturerID AND CategoryID=@CategoryID

So I would want to add a:

SortOrder = POSITION_IN_SELECT_RESULT

How would I accomplish this?

Answer 1

If you are talking about the input order in @InIds, it will likely require changing the function to also include the rank in the output. Assuming a numbers table:

SET NOCOUNT ON;
DECLARE @UpperLimit INT;
SET @UpperLimit = 200000;

;WITH n AS
(
    SELECT rn = ROW_NUMBER() OVER (ORDER BY s1.[object_id])
    FROM sys.objects AS s1
    CROSS JOIN sys.objects AS s2
    CROSS JOIN sys.objects AS s3
)
SELECT [Number] = rn - 1 INTO dbo.Numbers
FROM n WHERE rn <= @UpperLimit + 1;

CREATE UNIQUE CLUSTERED INDEX n ON dbo.Numbers([Number]);

You can create a function like this:

CREATE FUNCTION dbo.Split
(
    @List       VARCHAR(MAX),
    @Delimiter  VARCHAR(10)
)
RETURNS TABLE
AS
    RETURN
    (
        SELECT 
            [Position] = ROW_NUMBER() OVER (ORDER BY [Number]),
            [Value] = CONVERT(INT, 
                SUBSTRING(@List, [Number],
                CHARINDEX
                (
                    @Delimiter, @List + @Delimiter, [Number]
                ) - [Number]))
        FROM dbo.Numbers
        WHERE Number <= LEN(@List)
            AND SUBSTRING
            (
                @Delimiter + @List, [Number], LEN(@Delimiter)
            ) = @Delimiter
    );
GO

So now your UPDATE could look something like this:

UPDATE i SET 
    [Order]    = f.[Position],
    IsDeleted  = 0,
    ModifiedOn = GETDATE(),
    ModifiedBy = 'DragDropSP' 
FROM dbo.StagingCategoryItems AS i
INNER JOIN dbo.Split(@InIds, ',') AS f
ON i.ItemID = f.[Value]
WHERE IsDeleted = 1
AND   ManufacturerID = @ManufacturerID 
AND   CategoryID     = @CategoryID;

(I also removed your redundant check against the same table.)