Question

I have a SQL code for finding whether two words are anagram or not.

DECLARE @str1 VARCHAR(100), @str2 VARCHAR(100)
SELECT @str1 = 'mmaa', @str2 = 'mama'

IF LEN(@str1) <> LEN(@str2)
  BEGIN
    SELECT 'NOT EQUAL'
  END 

ELSE
  BEGIN

    IF (SELECT COUNT(*) FROM

    (

    select  substring(@str1, number, 1) as data
        from    master..spt_values as m 
        where   m.type='p' and number <= len(@str1) AND number > 0

    UNION 

    select  substring(@str2, number, 1) as data
        from    master..spt_values as m 
        where   m.type='p' and number <= len(@str2) AND number > 0
        )
t)

= LEN(@str1)


    SELECT '1 anagram'
ELSE

SELECT '0 not anagram'
END

But for words like mmaa and mama this program returns not anagram. But they are anagrams. How can I solve this problem?

Answer 1

rather crude, but how about:

Declare @S1 varChar(100) = 'mmaa'
Declare @S2 varChar(100) = 'mama'

Declare @c char(1)
Declare @i tinyint
Declare @o1 varChar(100) = ''
Declare @o2 varChar(100) = ''
While DataLength(@s1) > 0 Begin
   Set @c = Left(@s1, 1)
   Set @s1 = Substring(@s1, 2, len(@s1))
   Set @i = 1

   While @i <= Len(@o1) And @c > substring(@o1, @i, 1) Set @i += 1
   Set @o1 = left(@o1, @i-1) + @c + substring(@o1, @i, len(@o1))
End
While DataLength(@s2) > 0 Begin
   Set @c = Left(@s2, 1)
   Set @s2 = Substring(@s2, 2, len(@s2))
   Set @i = 1

   While @i <= Len(@o2) And @c > substring(@o2, @i, 1) Set @i += 1
   Set @o2 = left(@o2, @i-1) + @c + substring(@o2, @i, len(@o2))
End
Select case When @o1 = @o2 Then 'Anagram' Else 'Not Anagram' End

or to encapsulate the sort into a function,

    Create FUNCTION [dbo].[SortString](@s varChar(8000))
    RETURNS varChar(8000)
    As
    Begin
        Declare @c char(1)
        Declare @i int
        Declare @out varChar(8000) = left(@s, 1)
        While DataLength(@s) > 0 Begin
            Set @s = Substring(@s, 2, len(@s)-1)
            Set @c = Left(@s, 1)
            Set @i = 0
            While @i < Len(@out) And @c > substring(@out, @i+1, 1) Set @i += 1
            Set @out = case when @i < Len(@out) 
        then stuff(@out, @i+1, 0, @c)
        else  @out + @c end  
        End
        return  @out
    End