Question

I have a stored procedure where I need to run three separate SELECT statements and store the result in a variable.

I tried something like this:

SELECT @tier1MenuIds = Id
FROM TheGateKeeper.NavigationTier1
WHERE ([Page Name] = @currentSlug)

SELECT @tier2MenuIds = Id
FROM TheGateKeeper.NavigationTier2
WHERE ([Page Name] = @currentSlug)

SELECT @tier3MenuIds = Id
FROM TheGateKeeper.NavigationTier3
WHERE ([Page Name] = @currentSlug)

But it gives me an error saying

Incorrect syntax near ‘(‘.

The statement works if I remove the bottom two SELECTs. Any other options?

Edit: I am using SQL Server. Here is the full code:

CREATE PROCEDURE [TheGateKeeper].[editContent]
@description nvarchar(300),
@content nvarchar(MAX),
@title nvarchar(50),
@dateModified date,
@headerImageName nvarchar(100),
@slug nvarchar(50),
@id int

AS
BEGIN
    SET NOCOUNT ON;

    DECLARE @currentSlug as nvarchar(100);
    DECLARE @tier1MenuIds as int;
    DECLARE @tier2MenuIds as int;
    DECLARE @tier3MenuIds as int;

    /* Check if the post exists */
    SELECT @currentSlug =   Slug
    FROM         TheGateKeeper.Posts
    WHERE     (Id = @id)

    IF (@@ROWCOUNT = 1)
    BEGIN
    /* Temporarily unlink all menu items linking to post */
    SELECT @tier1MenuIds = Id
    FROM TheGateKeeper.NavigationTier1
    WHERE ([Page Name] = @currentSlug)

    SELECT @tier2MenuIds = Id
    FROM TheGateKeeper.NavigationTier2
    WHERE ([Page Name] = @currentSlug)

    SELECT @tier3MenuIds = Id
    FROM TheGateKeeper.NavigationTier3
    WHERE ([Page Name] = @currentSlug)

    /* Update the post in the database */
    UPDATE Posts
    SET (Description = @description, [Content] = @content, Title = @title, [Date Modified] =@dateModified, HeaderImageName = @headerImageName, slug =@slug)
    WHERE id = @id

    RETURN 1

    END

    ELSE
    BEGIN
    RETURN 0
    END

Answer 1

Remove the parentheses from your UPDATE statement; they are unnecessary.

Your update statement should be:

UPDATE Posts
SET Description = @description, [Content] = @content, Title = @title, 
    [Date Modified] =@dateModified, HeaderImageName = @headerImageName, 
    slug =@slug
WHERE id = @id