Question

I have a string “aa::bb::aa”

and need to turn it in to “aa, bb, aa”

I have tried

translate(string,':',', ')

but this returns “aa,,bb,,aa”

How can this be done.

Answer 1

A very simple solution (that will work as long as your string value doesn’t have spaces):

translate(normalize-space(translate('aa::bb::cc',':',' ')),' ',',')

1. translate “:’ into ” “
2. normalize-space() to collapse multiple whitespace characters into a single space ” “
3. translate single spaces ” ” into “,”

A more robust solution would be to use a recursive template:

<xsl:template name="replace-string">
    <xsl:param name="text"/>
    <xsl:param name="replace"/>
    <xsl:param name="with"/>
    <xsl:choose>
      <xsl:when test="contains($text,$replace)">
        <xsl:value-of select="substring-before($text,$replace)"/>
        <xsl:value-of select="$with"/>
        <xsl:call-template name="replace-string">
          <xsl:with-param name="text"
select="substring-after($text,$replace)"/>
          <xsl:with-param name="replace" select="$replace"/>
          <xsl:with-param name="with" select="$with"/>
        </xsl:call-template>
      </xsl:when>
      <xsl:otherwise>
        <xsl:value-of select="$text"/>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>

You can use it like this:

<xsl:call-template name="replace-string">
  <xsl:with-param name="text" select="'aa::bb::cc'"/>
  <xsl:with-param name="replace" select="'::'" />
  <xsl:with-param name="with" select="','"/>
</xsl:call-template>