Question

I have a table called dbo.Node:

NodeID      int
ParentNodeID    int
Title

The following functions shows the hierarchy

<cffunction name="getNodePath" returnType="string">
    <cfargument name="NodeID" required="false" default="">

    <cfset var qryNode = "">

    <cfif NOT isNumeric(arguments.nodeID)>
        <cfreturn "">
    </cfif>

    <cfquery name="qryNode" cachedWithin="#CreateTimeSpan(0,0,1,0)#">
        SELECT  ParentNodeID, Title
        FROM    dbo.Node WITH (NOLOCK)
        WHERE   NodeID = <cfqueryparam CFSQLType="CF_SQL_INTEGER" value="#arguments.NodeID#">
    </cfquery>      

    <cfreturn getNodePath(qryNode.ParentNodeID) & qryNode.Title & " &raquo; ">
</cffunction>

This code uses cacheWithin because it is known that many of the same parent path will be called. On average this gets called about 20 times from the original page. Overall it gets called 100s of times because of the recursive nature of the query. Furthermore this function returns a string. This means the formatting is in the model not the view.

Is there a way to replace this with a CTE?

Answer 1

Version with CTE

<cfset var qryNode = "">
<cfset var lstPath = "">

<cfif NOT isNumeric(arguments.nodeID)>
    <cfreturn QueryNew("Empty")>
</cfif>

<cfquery name="qryNode">
    WITH Family AS ( 

        SELECT  N.NodeID, ISNULL(N.ParentNodeID, '') AS ParentNodeID, Slug, N.Title, N.Kind, 0 AS Depth, N.CreateDate
        FROM    dbo.vwNode N WITH (NOLOCK)
        WHERE   NodeID = TRY_CONVERT(int, <cfqueryparam cfsqltype="CF_SQL_INTEGER" value="#arguments.NodeID#">)

        UNION ALL 

        SELECT  N2.NodeID, ISNULL(N2.ParentNodeID, '') AS ParentNodeID, N2.Slug,  N2.Title, N2.Kind, Depth + 1, N2.CreateDate
        FROM    dbo.vwNode N2 WITH (NOLOCK)

        INNER JOIN  Family 
        ON      Family.ParentNodeID = N2.NodeID
        WHERE   PrimaryRecord = 0 
        ) 


    SELECT  NodeID, ParentNodeID, Slug, Title, Kind, Depth, CreateDate
    FROM    Family
    ORDER BY Depth DESC
</cfquery>      

<cfreturn qryNode>

The With statement replaces the recursive call. This function is now called only about 20 times. There is no need to cache the results because they will not get reused. The function now returns a query. The formatting is now on the view where it belongs