Question

I have a table which maintain version of record with their parent id
Eg

Table(Id,version,parentId)

I am trying to get all the related record from given Id value

;WITH CTE (Id,ParentId)
AS
(
Select T1.Id,T1.ParentId
From Table T1
Where T1.ID = @Id or T1.ParentId=@Id

Union All

Select T2.Id, T2.ParentId
From Table T2
     Inner Join CTE C on C.Id= T2.ParentId  
)

This works fine for when the main parent id (162527) is provided, it brings me the

Id      VersionNo   ParentId
162527      1.0         0
162530      1.1         162527
162531      1.2         162527
162532      1.2.1       162531
162533      1.2.1.1     162532
162534      1.2.2       162531
200346      1.2.2.1     162534
200354      1.2.2.1.1   200346

But When I pass 200354 as Id, it returns me

200346  1.2.2.1     162534
200354  1.2.2.1.1   200346

But I want the all related record when an id is given.

Any help

Thanks

Answer 1

declare @Table table (id int, parentid int)

declare @id int, @ParentId int

select @id = 162530 

insert into @Table
select 162527, 0 union all
select 162530, 162527 union all
select 162531, 162527 union all
select 162532, 162531 union all
select 162533, 162532 union all
select 162534, 162531 union all
select 200346, 162534 union all
select 200354, 200346

;WITH Parents
AS
(
    Select T1.Id, T1.ParentId from @Table T1 where Id = @Id
    Union All
    Select T2.Id, T2.ParentId
    From @Table T2 Inner Join Parents C on C.ParentId = T2.Id
)
select @ParentId = P.id
from Parents as P
where parentid = 0

;WITH Children
AS
(
    Select T1.Id, T1.ParentId from @Table T1 where Id = @ParentId
    Union All
    Select T2.Id, T2.ParentId
    From @Table T2 Inner Join Children C on C.Id = T2.parentid
)
select *
from Children

Previous one

;WITH Children (Id,ParentId)
AS
(
    Select T1.Id, T1.ParentId from @Table T1 where Id = @Id
    Union All
    Select T2.Id, T2.ParentId
    From @Table T2 Inner Join Children C on C.ParentId = T2.Id
),Parents (Id,ParentId)
AS
(
    Select T1.Id, T1.ParentId from @Table T1 where Id = @Id
    Union All
    Select T2.Id, T2.ParentId
    From @Table T2 Inner Join Parents C on C.Id = T2.parentId
)
select * from Parents
union
select * from Children