Question

I have a table with this data in SQL Server :

Id
=====
1
12e
5 

and I want to order this data like this:

id
====
1
5
12e 

My id column is of type nvarchar(50) and I can’t convert it to int.

Is this possible that I sort the data in this way?

Answer 1

I’d actually use something along the lines of this function, though be warned that it’s not going to be super-speedy. I’ve modified that function to return only the numbers:

CREATE FUNCTION dbo.UDF_ParseNumericChars
(
  @string VARCHAR(8000)
)
RETURNS VARCHAR(8000)
WITH SCHEMABINDING
AS
BEGIN
  DECLARE @IncorrectCharLoc SMALLINT
  SET @IncorrectCharLoc = PATINDEX('%[^0-9]%', @string)
  WHILE @IncorrectCharLoc > 0
  BEGIN
    SET @string = STUFF(@string, @IncorrectCharLoc, 1, '')
    SET @IncorrectCharLoc = PATINDEX('%[^0-9]%', @string)
  END
  SET @string = @string
  RETURN @string
END
GO

Once you create that function, then you can do your sort like this:

  SELECT YourMixedColumn
    FROM YourTable
ORDER BY CONVERT(INT, dbo.UDF_ParseNumericChars(YourMixedColumn))