Question

I have a table with two relevant columns, an ID and a VARRAY of doubles representing coordinates like this: (x1, y1, x2, y2, x3, y3, …). The length of this array varies from four to dozens.

I need to write a view that takes all of these rows and expands each of them into several rows with an order field, like this:

ID order  X   Y
 1   1    x1  y1
 1   2    x2  y2
 1   3    x3  y3
 2   1    x1  y1
 2   2    x2  y2
 2   3    x3  y3

Google is no help, and being someone only mediocre at SQL (and mostly in PostgreSQL), the Oracle documentation is impossible to find advanced things in.

Answer 1

I for myself like piplined tables, heres a solution that uses it:

create or replace type my_res_typ as object
(
  v_id    number,
  v_order number,
  x       number,
  y       number
)
;
/

CREATE OR REPLACE TYPE my_res_tab AS TABLE OF my_res_typ;
/

create or replace function get_coordinates return my_res_tab
  pipelined is

  Result my_res_typ := my_res_typ(null, null, null, null);
  seq    number;
  i      integer;
begin

  for r in (select * from my_table) loop
    seq := 1;

    i := r.coordinates.first;
    while i < r.coordinates.last loop
      Result.v_id    := r.id;
      Result.v_order := seq;
      Result.x       := r.coordinates(i);
      Result.y       := r.coordinates(i + 1);

      pipe row(Result);
      seq := seq + 1;
      i   := i + 2;
    end loop;

  end loop;

  return;
end get_coordinates;
/

now you can query it like this:

select * from table(get_coordinates);

I used

my_table

as the table name