Question

I have a test function which would sanitize phone nos and allow only nos and characters “x” or “X” to be stored. I have it to where it does most of it other than it allows multiple x’s which I don’t want. Can anybody help me add it to the regular expression also let me know if you spot potential issues ?

CREATE Function [dbo].[RemoveAlphaCharacters](@Temp VarChar(1000))
Returns VarChar(1000)
AS
Begin

    While PatIndex('%[^0-9,x,X]%', @Temp) > 0
        Set @Temp = Stuff(@Temp, PatIndex('%[^0-9,x,X]%', @Temp), 1, '')

    Return @TEmp
End

Answer 1

The problem with PATINDEX here is that it can’t really determine that the pattern should change after it hits a string for the first time. So maybe this approach will be simpler:

CREATE FUNCTION [dbo].[RemoveAlphaCharacters]
(
    @Temp VARCHAR(1000)
)
RETURNS VARCHAR(1000)
AS
BEGIN
    DECLARE @i INT, @hitX BIT, @t VARCHAR(1000), @c CHAR(1);

    SELECT @i = 1, @hitX = 0, @t = '';

    WHILE @i <= LEN(@Temp)
    BEGIN
        SET @c = SUBSTRING(@Temp, @i, 1);
        IF LOWER(@c) = 'x' AND @hitX = 0
        BEGIN
            SET @t = @t + @c;
            SET @hitX = 1;
        END
        IF @c LIKE '[0-9]'
        BEGIN
            SET @t = @t + @c;
        END 

        SET @i = @i + 1;
    END
    RETURN(@t);
END
GO

SELECT dbo.RemoveAlphaCharacters('401-867-9092');
SELECT dbo.RemoveAlphaCharacters('401-867-9092x32');
SELECT dbo.RemoveAlphaCharacters('401-867-9092x32x54');

Results:

4018679092
4018679092x32
4018679092x3254