Question

I have a TIBquery object on one of the forms, which performing a heavy query, and the form freezing for a while.

• Could this “freezing” be prevented, and how ?

Answer 1

The database query is blocking your UI thread. Use a background thread for your query. A similar topic is already covered here and here.

---

You asked for an example, so here is one. Note that code is pseudo since it works with a plain TQuery, skips all the setting up, tearing down, error checking and is contained directly in the main form’s unit. It just illustrates one way to solve your problem.

  //  Create a descendant of TThread. This thread will execute your query
  //  asynchronously.
  TMyQueryThread = class(TThread)
  private
    FQueryString: string;
    FMyQuery: TQuery;
  protected
    procedure Execute; override;
  public
    constructor Create(QueryString: string);
    destructor Destroy; override;
    property MyQuery: TQuery read FMyQuery;
  end;

//  This processes the query result. Do whatever you need to do with the data,
//  but remember to do it quick. Otherwise you will freeze your UI again.
procedure ProcessResult(Data: TDataSet);
begin
  // process the data
  while not Data.Eof do
    Data.Next;
end;

//  This will be called when the thread terminates. 
//
//  Context: The code in here is executed in the main thread.
procedure TForm1.HandleThreadTerminate(Sender: TObject);
var
  SourceThread: TMyQueryThread;
begin
  SourceThread:= TMyQueryThread(Sender);
  // invoke data processing
  ProcessResult(SourceThread.MyQuery);
end;

//  When the user decides to run the query we create our thread. This call 
//  will take minimal time, so it doesn't block the UI.
//
//  Context: The code in here is executed in the main thread.
procedure TForm1.Button1Click(Sender: TObject);
begin
  with TMyQueryThread.Create('SELECT * FROM Table') do
  begin
    // we want to know when the thread finished its work so register for the event
    OnTerminate := HandleThreadTerminate;
    // this will free the thread object after OnTerminate has been called
    FreeOnTerminate := True;
  end;
end;

{ TMyQueryThread }

//  Constructor of the thread class. This takes the sql string to be executed.
//
//  Context: In this example, the code in here is executed in the main thread.
constructor TMyQueryThread.Create(QueryString: string);
begin
  // don't forget to call inherited constructor; tell it to start running immediately
  inherited Create(False);
  // save query string
  FQueryString := QueryString;
end;

//  Do the work which used to freeze your UI.
//
//  Context: The code in here does NOT run in the main thread.
procedure TMyQueryThread.Execute;
begin
  // mock query - this is your TIBQuery
  FMyQuery:= TQuery.Create(nil);
  with FMyQuery do
  begin
    SQL.Text:= FQueryString;
    // this will take a while but it doesn't matter because it only blocks the current thread, not the main thread
    Open;
  end;
end;

destructor TMyQueryThread.Destroy;
begin
  FMyQuery.Free;
  inherited;
end;

This works fine for the DB components I use. Be careful not to do any UI related activities in the Execute. The code shares a TQuery between the main thread and the query thread. It might be necessary that you not only create the query inside the thread, but also the database connection. You should probably use one connection per every thread you query the database from.