Question

I have a two level hash %chainro , each key of $chainro{$ro}{$id}points to an array. The following code is to iterate through the first level of hash, $chainro->{$ro}. I can guess what
does my $file = ${$chainro->{$ro}->$id}}[$i]; aim to perform. However, I do not know why ${$chainro->{$ro}->{$id}}was written this way? In specific, why do we need to add ${ } to wrap the $chainro->${ro}->{$id}

foreach my $id (keys %{$chainro->{$ro}})
{
   $size = $#{$chainro->{$ro}->{$id}};
   for ($i=0; $i<$size; $i++)
   {
     my $file = ${$chainro->{$ro}->{$id}}[$i];
    }
}

Answer 1

${ EXPR1 }[ EXPR2 ]

is an alternate way of writing

EXPR1->[ EXPR2 ]

so

${ $chainro->{$ro}->{$id} }[$i]

can be written as

$chainro->{$ro}->{$id}->[$i]

or even as

$chainro->{$ro}{$id}[$i]

---

Cleaned up:

for my $id (keys %{ $chainro->{$ro} }) {
   my $files = $chainro->{$ro}{$id};
   for my $i (0..$#$files) {
      my $file = $files->[$i];
      ...
   }
}

Or if you don’t need $i:

for my $id (keys %{ $chainro->{$ro} }) {
   my $files = $chainro->{$ro}{$id};
   for my $file (@$files) {
      ...
   }
}