Question

I have a unit something like this

type
 TMyClass = Class(TObject)
private
 AnInteger      : Integer;
 MyThreadHandle : DWORD;
 procedure MyPrivateProcedure;
public
 procedure MyPublicProcedure;
end;

procedure TMyClass.MyPrivateProcedure;
 procedure MyThread; stdcall;
 begin
  if AnInteger <> 0 then MyPublicProcedure;
 end;
var
 DummyID: DWORD;
begin
  MyThreadHandle := CreateThread(NIL,0,@MyThread,NIL,0, DummyID);
end;

procedure TMyClass.MyPublicProcedure;
begin
 AnInteger := 0;
end;

My goal is to have a Thread (no TTthread please.) that can “access” the vars/functions/procedures just like it’s part of the class. This Example fails because it doesn’t have access to the vars nor to the procedure. This is just an example, I am aware that the Integer can’t change just like that. To me it’s just important to have a thread that is part of the class. I also tried to pass the integer as a pointer (which worked) to the thread but I still can’t access a procedure/function of the class. any ideas?

Answer 1

A thread has its own stack pointer, so you can’t access local variables or parameters (like the hidden Self parameter) in you MyThread local procedure (which BTW is declared wrong). Furthermore you can’t use local procedures for threads if they access variables (including Self) from the outer function. And if you want to use the 64bit compiler in the future, you can’t use local procedures for any callback.

In your case you just have to fix the declaration of your procedure and move it into the unit scope (make it a “stand alone” procedure. This allows you to use the thread-callback parameter for “Self”.

function MyThread(MyObj: TMyClass): DWORD; stdcall;
begin
  if MyObj.AnInteger <> 0 then
    MyObj.MyPublicProcedure;
  Result := 0;
end;

procedure TMyClass.MyPrivateProcedure;
var
  DummyID: DWORD;
begin
  MyThreadHandle := CreateThread(nil, 0, @MyThread, Self, 0, DummyID);
end;