Question

I have a UserControl that exposes a System.Type property. I want to make it settable at design time, like the BindingSource’s DataSource property. Ultimately, I would like the designer code to generate this:

this.EntityType = typeof(Company.Product.Class);

Where the class selection would come from the project’s registered Data Sources.

Right now I’m exposing a BindingSource directly for the effect, but I’d love to know how can I replicate its behavior for my control.

Answer 1

This post helped me with this same type of problem.

Visual Studio Design Time Property – Form List Drop Down

This is my implementation, it creates a drop down of types that are accessible from the current project, and filters them by their base class.

You have to add a reference to EnvDTE

    Public Class EditChildFormDesignerTypeEditor
    Inherits UITypeEditor

    Public Overrides Function GetEditStyle(ByVal context As ITypeDescriptorContext) As UITypeEditorEditStyle
        Return UITypeEditorEditStyle.DropDown
    End Function

    Public Overrides Function EditValue(ByVal context As ITypeDescriptorContext, ByVal provider As IServiceProvider, ByVal value As Object) As Object
        Dim edSvc = DirectCast(provider.GetService(GetType(IWindowsFormsEditorService)), IWindowsFormsEditorService)


        Dim dte As EnvDTE.DTE = context.GetService(GetType(EnvDTE.DTE))
        If dte Is Nothing Then Throw New InvalidOperationException("DTE not found.")

        Dim lb As New ListBox()

        For Each proj As Project In dte.Solution.Projects
            For Each ce As CodeElement In proj.CodeModel.CodeElements
                If ce.Kind = vsCMElement.vsCMElementClass Then
                    Dim ccl As CodeClass = ce
                    If ccl.IsDerivedFrom(GetType(frmEditChildItem).FullName) Then
                        Dim Tp As Type = Type.GetType(ccl.FullName)
                        If Tp IsNot Nothing Then
                            lb.Items.Add(Tp)
                        End If
                    End If
                End If
            Next
        Next

        If value IsNot Nothing Then
            lb.SelectedItem = value
        End If

        edSvc.DropDownControl(lb)

        value = DirectCast(lb.SelectedItem, Type)

        Return value
    End Function
End Class