Question

I have a weird problem and I don’t know where I am doing wrong.

I have the following code. Please look at the end of it that’s where it fails I commented it:

var
  IDH:PImageDosHeader;
  INH:PImageNtHeaders;
  ISH:PImageSectionHeader;
  buf:Pointer;
  FS:TFileStream;
  ep,tmp1,tmp2:DWORD;
  i:Word;
begin
  if OpenDialog1.Execute then
    begin
        FS:=TFileStream.Create(OpenDialog1.FileName,fmOpenRead or fmShareDenyNone);
        GetMem(buf,FS.size);
        FS.Read(buf^,FS.Size);
        FS.Free;
        IDH:=PImageDosHeader(buf);
        INH:=PImageNtHeaders(DWORD(buf) + DWORD(IDH^._lfanew));
        ep:=INH^.OptionalHeader.AddressOfEntryPoint;
        for i:=0 to INH^.FileHeader.NumberOfSections - 1 do
        begin
          ISH:=PimageSectionHeader(DWORD(INH) + sizeof(TImageNtHeaders) + i * sizeof(TImageSectionHeader));
          tmp1:=ISH^.VirtualAddress;
          tmp2:=ISH^.VirtualAddress + ISH^.Misc.VirtualSize;
          ShowMessageFmt('%d -> %d .. %d',[ep,tmp1,tmp2]);
          if ep in [tmp1..tmp2] then ShowMessage('Got it'); //This fails even if ep is in the defined interval. Why?
        end;
    end;
end;

Of course I can replace that line with

if (ep>=tmp1) and (ep<=tmp2) 

but I want to know what I am doing wrong.

Answer 1

A set is a collection of values of the same type. This type must be ordinal, and a variable of this type must have at most 256 possible values. (Official documentation) Hence, a set cannot contain integers, since there are more than 256 possible integers.

You could use the InRange function:

if InRange(ep, tmp1, tmp2) then

(uses Math).