Question

I have a workbook that I need to open and then copy the data from the first tab, and then paste it to the original workbook in which the script was created from.

The problem I am running into is that the workbook and the first tab will be named the same thing. So if the workbook name is OpenPOs-100255-08292012.xls the tab is going to be OpenPOs-100255-08292012. Next week though the excel sheet is going to be OpenPOs-200211-12495312.xls which means the tab is going to be OpenPOs-200211-12495312.

With the code I am using right now, is there a way to make it work for this kind of situation? I thought about making it so that the "Sheet 1" becomes the tab of the day? I thought about using `wsPOR.Sheets(wsPOR) but I have a feeling that is going to be coming back as an error. Can someone help please?

Sub Update_TNOOR()
    Dim wsTNO As Worksheet
    Dim wsTND As Worksheet
    Dim wsTNA As Worksheet
    Dim wbPOR As Workbook               'New Workbook
    Dim wbOOR As Workbook               'ThisWorkbook
    Dim lastrow As Long, lastrow2 As Long, fstcell As Long
    Dim strFile As String, NewFileType As String, filename As String

    Set wsTNO = Sheets("Tel-Nexx OOR")
    Set wsTND = Sheets("Tel-Nexx Data")
    Set wsTNA = Sheets("Tel-Nexx Archive")
    Set wbOOR = ThisWorkbook

    With Application
        .ScreenUpdating = False
        .DisplayAlerts = False
        .EnableEvents = False
    End With

    lastrow = wsTND.Range("A" & Rows.Count).End(xlUp).Row + 1
    wsTND.Range("A2:P" & lastrow).Delete

    strFile = Application.GetOpenFilename()
    NewFileType = "Excel Files 2007 (*.xls)"
    Set wbPOR = Application.Workbooks.Open(strFile)
    lastrow = wbPOR.Sheets("Sheet1").Range("A" & wbPOR.Sheets("Sheet1").Rows.Count).End(xlUp).Row
    wbPOR.Sheets("Sheet1").Range("A4:N" & lastrow).Copy wbOOR.Sheets("Tel-Nexx Data").Range("A2")
    wbPOR.Save
    wbPOR.Close


End Sub

Answer 1

Based on my comment above, your code, from strFile = Application.GetOpenFilename() to wbPOR.Close becomes:

strFile = Application.GetOpenFilename()
NewFileType = "Excel Files 2007 (*.xls)"

Set wbPOR = Application.Workbooks.Open(strFile)

Dim wsPOR As Worksheet
Set wsPOR = wbPOR.Sheets(Replace(wbPOR.Name, ".xls", ""))

lastrow = wsPOR.Range("A" & wsPOR.Rows.Count).End(xlUp).Row

wsPOR.Range("A4:N" & lastrow).Copy wbOOR.Sheets("Tel-Nexx Data").Range("A2")

wbPOR.Save
wbPOR.Close