Question

I have a xml document which has a node that contains a proper name then a dash (-) followed by a description. I want to only display the proper name.

<productroot>
   <name>Proper name - lots of text not relevant to my display.</name>
</productroot>

Thanks

Answer 1

Here is a complete solution:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match=
  "name/text()[contains(., ' -')]">
  <xsl:value-of select="substring-before(., ' -')"/>
 </xsl:template>
</xsl:stylesheet>

when this transformation is applied on the XML document below:

<productroot>
    <name>Proper name1 - Irrelevant 1</name>
    <name>Proper name2 - Irrelevant 2</name>
    <name>Proper name3 - Irrelevant 3</name>
    <name>Proper name4 - Irrelevant 4</name>
    <name>Proper name5 - Irrelevant 5</name>
</productroot>

the wanted, correct result is produced:

<productroot>
   <name>Proper name1</name>
   <name>Proper name2</name>
   <name>Proper name3</name>
   <name>Proper name4</name>
   <name>Proper name5</name>
</productroot>

Explanation:

1. Overriding the identity rule.

2. Use of the standard XPath functions contains() and substring-before().