Question

I have a xml file main.xml with following markup and data.

 main.xml

 <xml>
    <content>
     <para>
     This is a para.
     </para>
     <sub para>
     This is para.
     </sub para>
     </content>
</xml>

I have another xml file keyword.xml with list of keywords that we need to find any where in above xml and replace the keyword value.

keyword.xml

 <xml>
     <keywordList>
        <keyword>
            <value>para</value>
            <replace> paragraph </replace> 
        </keyword>
        <keyword>
            <value>is</value>
            <replace>IS</replace> 
        </keyword>
  </xml>

Can we do it in xslt so that the output should be

    output
        <xml>
    <content>
     <para>
     This IS a paragraph.
     </para>
     <sub para>
     This IS paragraph.
     </sub para>
     </content>
</xml>

Answer 1

This is an XSLT 1.0 solution (of course, can be used with XSLT 2.0, too):

<xsl:stylesheet version="1.0"
     xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
     xmlns:ext="http://exslt.org/common"
     xmlns:my="my:my">
        <xsl:output omit-xml-declaration="yes" indent="yes"/>
        <xsl:strip-space elements="*"/>

        <my:params xml:space="preserve">
            <pattern>
                <old>para</old>
                <new> paragraph </new>
            </pattern>
            <pattern>
                <old> is </old>
                <new> IS </new>
            </pattern>
        </my:params>

        <xsl:variable name="vrtfPats">
         <xsl:for-each select="document('')/*/my:params/*">
          <xsl:sort select="string-length(old)"
               data-type="number" order="descending"/>
           <xsl:copy-of select="."/>
         </xsl:for-each>
        </xsl:variable>

        <xsl:variable name="vPats" select=
         "ext:node-set($vrtfPats)/*"/>

            <xsl:template match="node()|@*">
              <xsl:copy>
               <xsl:apply-templates select="node()|@*"/>
              </xsl:copy>
          </xsl:template>

        <xsl:template match="text()" name="multiReplace" priority="2">
            <xsl:param name="pText" select="."/>
            <xsl:param name="pPatterns" select="$vPats"/>
            <xsl:if test=    "string-length($pText) >0">
                <xsl:variable name="vPat" select=
                "$vPats[starts-with($pText, old)][1]"/>

                <xsl:choose>
                    <xsl:when test="not($vPat)">
                        <xsl:copy-of select="substring($pText,1,1)"/>
                    </xsl:when>
                    <xsl:otherwise>
                        <xsl:copy-of select="$vPat/new/node()"/>
                    </xsl:otherwise>
                </xsl:choose>

                <xsl:call-template name="multiReplace">
                    <xsl:with-param name="pText" select=
                    "substring($pText,
                              1 + not($vPat) + string-length($vPat/old/node())
                              )"/>
                </xsl:call-template>
            </xsl:if>
        </xsl:template>
</xsl:stylesheet>

When this transformation is applied on the provided XML document (corrected to be well-formed):

<xml>
    <content>
        <para>
         This is a para.
      </para>
        <sub_para>
         This is para.
      </sub_para>
    </content>
</xml>

the wanted, correct result is produced:

<xml>
   <content>
      <para>
         This IS a  paragraph .
      </para>
      <sub_para>
         This IS  paragraph .
      </sub_para>
   </content>
</xml>

Explanation: The text is scanned character by character and the longest possible target string starting at that position in the text is replaced with its specified replacement.