Question

I have a XML File which contains user ids and names. I want to extract all elements where both of these attributes have a value.

This is my xml

<pens>
<pen id="A">
    <user name="USER1" email="USER1EMAIL" />
</pen>
<pen id="B">
    <user name="USER2" email="USER2EMAIL" />
</pen>
<pen id="C"></pen>
<pen id="D">
    <user name="USER3" email="USER3EMAIL" />
</pen>
</pens>

I need a out like this

A - USER1
B - USER2
D - USER3

I try it with XSL but I dont get it … can someone help please.
Thanks

Answer 1

When this XSLT:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:output omit-xml-declaration="no" indent="yes" method="text" />
  <xsl:strip-space elements="*" />

  <xsl:template match="user[@name][@email]">
    <xsl:value-of select="parent::*/@id" />
    <xsl:text> - </xsl:text>
    <xsl:value-of select="@name" />
    <xsl:text>&#10;</xsl:text>
  </xsl:template>

</xsl:stylesheet>

…is applied against your original XML:

<pens>
  <pen id="A">
    <user name="USER1" email="USER1EMAIL"/>
  </pen>
  <pen id="B">
    <user name="USER2" email="USER2EMAIL"/>
  </pen>
  <pen id="C"/>
  <pen id="D">
    <user name="USER3" email="USER3EMAIL"/>
  </pen>
</pens>

…the wanted result is produced:

A - USER1
B - USER2
D - USER3

Explanation:

• We set the @method attribute of the <xsl:output> element to have a value of text (since we are interested in text results).

• One template matches <user> elements that have @name and @email attributes defined.

• When one such <user> element is found, we output the value of its parent element’s @id attribute, a dash, the value of the element’s @name attribute, and finally, a newline character.

Saving this result to a file depends on which XSLT processor you are using. If you run your transformations via the command line (e.g., the way xsltproc does), you can do something like this:

$ xsltproc t.xsl input.xml > output.xml