Question

I have a xml that looks like below one. I need your help to transform the below xml to
remove all namespaces and also the “Return” tag. Appreciate if some one provides me the correct xsl.

I am tired of trying several thing.

Original XML:

<soapenv:Envelope xmlns:soapenv="http://www.w3.org/2003/05/soap-envelope">
<soapenv:Body>
<ns:Response xmlns:ns="http://demo.test.classes.com">
   <ns:return>
      <ns:person>
         <ns:personName></ns:personName>
         <ns:personAge></ns:personAge>
         <ns:personAddress>
            <ns:addressType>official</ns:addressType>
            <ns:addressLine1>official address line 1</ns:addressLine1>
         </ns:personAddress>
         <ns:personAddress>
            <ns:addressType>residence</ns:addressType>
            <ns:addressLine1>residence address line 1</ns:addressLine1>
         </ns:personAddress>         
      </ns:person>
   </ns:return>
</ns:Response>
</soapenv:Body>
</soapenv:Envelope>  

Expected XML after transformation:

<Response>
      <person>
         <personName></personName>
         <personAge></personAge>
         <personAddress>
            <addressType>official</addressType>
            <addressLine1>official address line 1</addressLine1>
         </personAddress>
         <personAddress>
            <addressType>residence</addressType>
            <addressLine1>residence address line 1</addressLine1>
         </personAddress>         
      </person>
</Response>  

This is the XSLT, I am using now. But this is not generated the xml which I need.

<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes" />

    <xsl:template match="/|comment()|processing-instruction()">
        <xsl:copy>
            <xsl:apply-templates />
        </xsl:copy>
    </xsl:template>

    <xsl:template match="*">
        <xsl:element name="{local-name()}">
            <xsl:apply-templates select="@*|node()" />
        </xsl:element>
    </xsl:template>

    <xsl:template match="@*">
        <xsl:attribute name="{local-name()}">
      <xsl:value-of select="." />
    </xsl:attribute>
    </xsl:template>

    <xsl:template match="Response/return" />

</xsl:stylesheet>

Answer 1

Remember that SOAP does not use any name-spaced attributes, so you can afford to simplify a little bit. This very short XSLT 1.0 style-sheet will do the trick.

<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:soapenv="http://www.w3.org/2003/05/soap-envelope"
    xmlns:ns="http://demo.test.classes.com"
    exclude-result-prefixes="xsl soapenv ns">
<xsl:output method="xml" indent="yes" />
<xsl:strip-space elements="*" />

<xsl:template match="*">
 <xsl:element name="{local-name()}">
  <xsl:apply-templates select="@*|node()" />
 </xsl:element>
</xsl:template>

<xsl:template match="ns:return|soapenv:Envelope|soapenv:Body">
  <xsl:apply-templates/>
</xsl:template>

</xsl:stylesheet>

As this is a SOAP document, you are unlikely to be interested in comments and PI’s. However if you really want them back in, then it is a trivial matter to adjust.