Question

I have a XML that looks like this (arbitrary XML input)

<NodeLevel1>
    <NodeLevel2>
        <NodeLevel3>
            Sample text 1
        </NodeLevel3>
    </NodeLevel2>

    <NodeLevel2>
        .
        .
        .
        ... <NodeLevelN>
                Some deep thought
            </NodeLevelN>
    </NodeLevel2>

    <NodeLevel2>
        Sample text 2
    </NodeLevel2>
    Sample text 3
</NodeLevel1>

What I would like to have after XSLT transformation is 4 new XMLs containing just a single text node like the following 4 XMLs:

1.

    <NodeLevel1>
        <NodeLevel2>
            <NodeLevel3>
                Sample text 1
            </NodeLevel3>
        </NodeLevel2>
    </NodeLevel1>

2.

    <NodeLevel1>    
        <NodeLevel2>
            .
            .
            .
            ... <NodeLevelN>
                    Some deep thought
                </NodeLevelN>
        </NodeLevel2>
    </NodeLevel1>

3.

    <NodeLevel1>
        <NodeLevel2>
            Sample text 2
        </NodeLevel2>
    </NodeLevel1>

4.

    <NodeLevel1>
        Sample text 3
    </NodeLevel1>

What is the best way to do that? I’m using C++ (I can use libxml2 and libxslt)
Thanks!

Answer 1

I would use XSLT 2.0 with xsl:result-document or in your case with libxslt you can also use the exsl:document extension element:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="1.0"
  xmlns:exsl="http://exslt.org/common"
  extension-element-prefixes="exsl"
  exclude-result-prefixes="exsl">

<xsl:template match="/">
  <xsl:apply-templates select="NodeLevel1/node()[self::* or self::text()[normalize-space()]]" mode="new-doc"/>
</xsl:template>

<xsl:template match="NodeLevel1/node()" mode="new-doc">
  <exsl:document href="result{position()}.xml">
    <NodeLevel1>
      <xsl:copy-of select="."/>
    </NodeLevel1>
  </exsl:document>
</xsl:template>

</xsl:stylesheet>

Thinking about the problem a bit more I have improved the stylesheet to work with any kind of root element:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="1.0"
  xmlns:exsl="http://exslt.org/common"
  extension-element-prefixes="exsl"
  exclude-result-prefixes="exsl">

<xsl:template match="/">
  <xsl:apply-templates select="*/node()[self::* or self::text()[normalize-space()]]" mode="new-doc"/>
</xsl:template>

<xsl:template match="/*/node()" mode="new-doc">
  <exsl:document href="result{position()}.xml">
    <xsl:element name="{name(..)}" namespace="{namespace-uri(..)}">
      <xsl:copy-of select="."/>
    </xsl:element>
  </exsl:document>
</xsl:template>

</xsl:stylesheet>

[edit]
If you want to use an XSLT 2.0 processor like Saxon or AltovaXML or XmlPrime here is an XSLT 2.0 stylesheet:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="2.0">

<xsl:template match="/">
  <xsl:apply-templates select="*/(* | text()[normalize-space()])" mode="new-doc"/>
</xsl:template>

<xsl:template match="/*/node()" mode="new-doc">
  <xsl:result-document href="result{position()}.xml">
    <xsl:element name="{name(..)}" namespace="{namespace-uri(..)}">
      <xsl:copy-of select="."/>
    </xsl:element>
  </xsl:result-document>
</xsl:template>

</xsl:stylesheet>