Question

I have a XSLT transformation:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

    <xsl:output method="xml"
                indent="yes"
                version="1.0"
                encoding="UTF-16"              
                standalone="yes"                        
                cdata-section-elements="title date referencenumber url company city state country postalcode description salary education jobtype category experience"/>

    <xsl:param name="currentDate"/>

    <xsl:template match="/response/result">
        <source>            
            <xsl:for-each select="//doc">
                <job>
                    <title>
                        <xsl:value-of select="str[@name='title']"/>
                    </title>
                    <date>
                        <xsl:value-of select="date[@name='ds_field_ad_publish']"/>
                    </date>
                    <referencenumber>
                        <xsl:value-of select="int[@name='nid']"/>
                    </referencenumber>
                </job>
            </xsl:for-each>            
        </source>
    </xsl:template>   

</xsl:stylesheet>

And here is my XML document:

<?xml version="1.0" encoding="UTF-8"?>
<response>
    <lst name="responseHeader">
        <int name="status">0</int>
        <int name="QTime">4</int>
        <lst name="params">
            <str name="wt">xml</str>
            <str name="fq">type:ad_vacancy is_organisation_nid:190908</str>
            <str name="rows">1000000</str>
        </lst>
    </lst>
    <result name="response" numFound="2" start="0">
        <doc>
            <!-- all my values -->
        </doc>
        <doc>
            <!-- all my values -->
        </doc>
        <doc>
            <!-- all my values -->
        </doc>
    </result>
</response>

I am matching /response/result and then looping through all the <doc> elements. Everything works fine, but at the top of my document I am seeing the values from <lst> element. Like this:

0
4

    xml
    type:ad_vacancy is_organisation_nid:190908
    1000000

I need to somehow escape that whole block, that my transformation would not match it. I have tried different expressions like: <xsl:template match="//response/result">, <xsl:template match="//response//result">. I also tried to add this into my transfromation:

<xsl:template match="/*">
    <xsl:apply-templates/>
</xsl:template>

But that did not helped as well. The values from <lst> still remains. Is there a way to get rid of them?

Answer 1

Just add this to your template: <xsl:template match="text() | @*"/>
It matches text nodes and attributes and since the template is empty it does nothing to them. It is actually a "built-in-template" –> http://www.w3.org/TR/xslt#built-in-rule

Your edited XSLT looks like this:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

<xsl:output method="xml"
    indent="yes"
    version="1.0"
    encoding="UTF-16"              
    standalone="yes"                        
    cdata-section-elements="title date referencenumber url company city state country postalcode description salary education jobtype category experience"/>

<xsl:param name="currentDate"/>

<xsl:template match="text() | @*"/>

<xsl:template match="/response/result">
    <source>            
        <xsl:for-each select="//doc">
            <job>
                <title>
                    <xsl:value-of select="str[@name='title']"/>
                </title>
                <date>
                    <xsl:value-of select="date[@name='ds_field_ad_publish']"/>
                </date>
                <referencenumber>
                    <xsl:value-of select="int[@name='nid']"/>
                </referencenumber>
            </job>
        </xsl:for-each>            
    </source>
</xsl:template>   

</xsl:stylesheet>